Sort out some more fonty stuff, mostly size
[gitweb] / gitweb.cgi
1 #!/usr/bin/perl
2
3 # gitweb - simple web interface to track changes in git repositories
4 #
5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
6 # (C) 2005, Christian Gierke
7 #
8 # This program is licensed under the GPLv2
9
10 use 5.008;
11 use strict;
12 use warnings;
13 # handle ACL in file access tests
14 use filetest 'access';
15 use CGI qw(:standard :escapeHTML -nosticky);
16 use CGI::Util qw(unescape);
17 use CGI::Carp qw(fatalsToBrowser set_message);
18 use Encode;
19 use Fcntl ':mode';
20 use File::Find qw();
21 use File::Basename qw(basename);
22 use Time::HiRes qw(gettimeofday tv_interval);
23 use Digest::MD5 qw(md5_hex);
24
25 binmode STDOUT, ':utf8';
26
27 if (!defined($CGI::VERSION) || $CGI::VERSION < 4.08) {
28 eval 'sub CGI::multi_param { CGI::param(@_) }'
29 }
30
31 our $t0 = [ gettimeofday() ];
32 our $number_of_git_cmds = 0;
33
34 BEGIN {
35 CGI->compile() if $ENV{'MOD_PERL'};
36 }
37
38 our $version = "2.34.1";
39
40 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
41 sub evaluate_uri {
42 our $cgi;
43
44 our $my_url = $cgi->url();
45 our $my_uri = $cgi->url(-absolute => 1);
46
47 # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
48 # needed and used only for URLs with nonempty PATH_INFO
49 our $base_url = $my_url;
50
51 # When the script is used as DirectoryIndex, the URL does not contain the name
52 # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
53 # have to do it ourselves. We make $path_info global because it's also used
54 # later on.
55 #
56 # Another issue with the script being the DirectoryIndex is that the resulting
57 # $my_url data is not the full script URL: this is good, because we want
58 # generated links to keep implying the script name if it wasn't explicitly
59 # indicated in the URL we're handling, but it means that $my_url cannot be used
60 # as base URL.
61 # Therefore, if we needed to strip PATH_INFO, then we know that we have
62 # to build the base URL ourselves:
63 our $path_info = decode_utf8($ENV{"PATH_INFO"});
64 if ($path_info) {
65 # $path_info has already been URL-decoded by the web server, but
66 # $my_url and $my_uri have not. URL-decode them so we can properly
67 # strip $path_info.
68 $my_url = unescape($my_url);
69 $my_uri = unescape($my_uri);
70 if ($my_url =~ s,\Q$path_info\E$,, &&
71 $my_uri =~ s,\Q$path_info\E$,, &&
72 defined $ENV{'SCRIPT_NAME'}) {
73 $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
74 }
75 }
76
77 # target of the home link on top of all pages
78 our $home_link = $my_uri || "/";
79 }
80
81 # core git executable to use
82 # this can just be "git" if your webserver has a sensible PATH
83 our $GIT = "/usr/bin/git";
84
85 # absolute fs-path which will be prepended to the project path
86 #our $projectroot = "/pub/scm";
87 our $projectroot = "/pub/git";
88
89 # fs traversing limit for getting project list
90 # the number is relative to the projectroot
91 our $project_maxdepth = 2007;
92
93 # string of the home link on top of all pages
94 our $home_link_str = "projects";
95
96 # extra breadcrumbs preceding the home link
97 our @extra_breadcrumbs = ();
98
99 # name of your site or organization to appear in page titles
100 # replace this with something more descriptive for clearer bookmarks
101 our $site_name = ""
102 || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
103
104 # html snippet to include in the <head> section of each page
105 our $site_html_head_string = "";
106 # filename of html text to include at top of each page
107 our $site_header = "";
108 # html text to include at home page
109 our $home_text = "indextext.html";
110 # filename of html text to include at bottom of each page
111 our $site_footer = "";
112
113 # URI of stylesheets
114 our @stylesheets = ("static/gitweb.css");
115 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
116 our $stylesheet = undef;
117 # URI of GIT logo (72x27 size)
118 our $logo = "static/git-logo.png";
119 # URI of GIT favicon, assumed to be image/png type
120 our $favicon = "static/git-favicon.png";
121 # URI of gitweb.js (JavaScript code for gitweb)
122 our $javascript = "static/gitweb.js";
123
124 # URI and label (title) of GIT logo link
125 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
126 #our $logo_label = "git documentation";
127 our $logo_url = "http://git-scm.com/";
128 our $logo_label = "git homepage";
129
130 # source of projects list
131 our $projects_list = "";
132
133 # the width (in characters) of the projects list "Description" column
134 our $projects_list_description_width = 25;
135
136 # group projects by category on the projects list
137 # (enabled if this variable evaluates to true)
138 our $projects_list_group_categories = 0;
139
140 # default category if none specified
141 # (leave the empty string for no category)
142 our $project_list_default_category = "";
143
144 # default order of projects list
145 # valid values are none, project, descr, owner, and age
146 our $default_projects_order = "project";
147
148 # show repository only if this file exists
149 # (only effective if this variable evaluates to true)
150 our $export_ok = "";
151
152 # don't generate age column on the projects list page
153 our $omit_age_column = 0;
154
155 # don't generate information about owners of repositories
156 our $omit_owner=0;
157
158 # show repository only if this subroutine returns true
159 # when given the path to the project, for example:
160 # sub { return -e "$_[0]/git-daemon-export-ok"; }
161 our $export_auth_hook = undef;
162
163 # only allow viewing of repositories also shown on the overview page
164 our $strict_export = "";
165
166 # list of git base URLs used for URL to where fetch project from,
167 # i.e. full URL is "$git_base_url/$project"
168 our @git_base_url_list = grep { $_ ne '' } ("");
169
170 # default blob_plain mimetype and default charset for text/plain blob
171 our $default_blob_plain_mimetype = 'text/plain';
172 our $default_text_plain_charset = undef;
173
174 # file to use for guessing MIME types before trying /etc/mime.types
175 # (relative to the current git repository)
176 our $mimetypes_file = undef;
177
178 # assume this charset if line contains non-UTF-8 characters;
179 # it should be valid encoding (see Encoding::Supported(3pm) for list),
180 # for which encoding all byte sequences are valid, for example
181 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
182 # could be even 'utf-8' for the old behavior)
183 our $fallback_encoding = 'latin1';
184
185 # rename detection options for git-diff and git-diff-tree
186 # - default is '-M', with the cost proportional to
187 # (number of removed files) * (number of new files).
188 # - more costly is '-C' (which implies '-M'), with the cost proportional to
189 # (number of changed files + number of removed files) * (number of new files)
190 # - even more costly is '-C', '--find-copies-harder' with cost
191 # (number of files in the original tree) * (number of new files)
192 # - one might want to include '-B' option, e.g. '-B', '-M'
193 our @diff_opts = ('-M'); # taken from git_commit
194
195 # Disables features that would allow repository owners to inject script into
196 # the gitweb domain.
197 our $prevent_xss = 0;
198
199 # Path to the highlight executable to use (must be the one from
200 # http://www.andre-simon.de due to assumptions about parameters and output).
201 # Useful if highlight is not installed on your webserver's PATH.
202 # [Default: highlight]
203 our $highlight_bin = "highlight";
204
205 # information about snapshot formats that gitweb is capable of serving
206 our %known_snapshot_formats = (
207 # name => {
208 # 'display' => display name,
209 # 'type' => mime type,
210 # 'suffix' => filename suffix,
211 # 'format' => --format for git-archive,
212 # 'compressor' => [compressor command and arguments]
213 # (array reference, optional)
214 # 'disabled' => boolean (optional)}
215 #
216 'tgz' => {
217 'display' => 'tar.gz',
218 'type' => 'application/x-gzip',
219 'suffix' => '.tar.gz',
220 'format' => 'tar',
221 'compressor' => ['gzip', '-n']},
222
223 'tbz2' => {
224 'display' => 'tar.bz2',
225 'type' => 'application/x-bzip2',
226 'suffix' => '.tar.bz2',
227 'format' => 'tar',
228 'compressor' => ['bzip2']},
229
230 'txz' => {
231 'display' => 'tar.xz',
232 'type' => 'application/x-xz',
233 'suffix' => '.tar.xz',
234 'format' => 'tar',
235 'compressor' => ['xz'],
236 'disabled' => 1},
237
238 'zip' => {
239 'display' => 'zip',
240 'type' => 'application/x-zip',
241 'suffix' => '.zip',
242 'format' => 'zip'},
243 );
244
245 # Aliases so we understand old gitweb.snapshot values in repository
246 # configuration.
247 our %known_snapshot_format_aliases = (
248 'gzip' => 'tgz',
249 'bzip2' => 'tbz2',
250 'xz' => 'txz',
251
252 # backward compatibility: legacy gitweb config support
253 'x-gzip' => undef, 'gz' => undef,
254 'x-bzip2' => undef, 'bz2' => undef,
255 'x-zip' => undef, '' => undef,
256 );
257
258 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
259 # are changed, it may be appropriate to change these values too via
260 # $GITWEB_CONFIG.
261 our %avatar_size = (
262 'default' => 16,
263 'double' => 32
264 );
265
266 # Used to set the maximum load that we will still respond to gitweb queries.
267 # If server load exceed this value then return "503 server busy" error.
268 # If gitweb cannot determined server load, it is taken to be 0.
269 # Leave it undefined (or set to 'undef') to turn off load checking.
270 our $maxload = 300;
271
272 # configuration for 'highlight' (http://www.andre-simon.de/)
273 # match by basename
274 our %highlight_basename = (
275 #'Program' => 'py',
276 #'Library' => 'py',
277 'SConstruct' => 'py', # SCons equivalent of Makefile
278 'Makefile' => 'make',
279 );
280 # match by extension
281 our %highlight_ext = (
282 # main extensions, defining name of syntax;
283 # see files in /usr/share/highlight/langDefs/ directory
284 (map { $_ => $_ } qw(py rb java css js tex bib xml awk bat ini spec tcl sql)),
285 # alternate extensions, see /etc/highlight/filetypes.conf
286 (map { $_ => 'c' } qw(c h)),
287 (map { $_ => 'sh' } qw(sh bash zsh ksh)),
288 (map { $_ => 'cpp' } qw(cpp cxx c++ cc)),
289 (map { $_ => 'php' } qw(php php3 php4 php5 phps)),
290 (map { $_ => 'pl' } qw(pl perl pm)), # perhaps also 'cgi'
291 (map { $_ => 'make'} qw(make mak mk)),
292 (map { $_ => 'xml' } qw(xml xhtml html htm)),
293 );
294
295 # You define site-wide feature defaults here; override them with
296 # $GITWEB_CONFIG as necessary.
297 our %feature = (
298 # feature => {
299 # 'sub' => feature-sub (subroutine),
300 # 'override' => allow-override (boolean),
301 # 'default' => [ default options...] (array reference)}
302 #
303 # if feature is overridable (it means that allow-override has true value),
304 # then feature-sub will be called with default options as parameters;
305 # return value of feature-sub indicates if to enable specified feature
306 #
307 # if there is no 'sub' key (no feature-sub), then feature cannot be
308 # overridden
309 #
310 # use gitweb_get_feature(<feature>) to retrieve the <feature> value
311 # (an array) or gitweb_check_feature(<feature>) to check if <feature>
312 # is enabled
313
314 # Enable the 'blame' blob view, showing the last commit that modified
315 # each line in the file. This can be very CPU-intensive.
316
317 # To enable system wide have in $GITWEB_CONFIG
318 # $feature{'blame'}{'default'} = [1];
319 # To have project specific config enable override in $GITWEB_CONFIG
320 # $feature{'blame'}{'override'} = 1;
321 # and in project config gitweb.blame = 0|1;
322 'blame' => {
323 'sub' => sub { feature_bool('blame', @_) },
324 'override' => 0,
325 'default' => [0]},
326
327 # Enable the 'snapshot' link, providing a compressed archive of any
328 # tree. This can potentially generate high traffic if you have large
329 # project.
330
331 # Value is a list of formats defined in %known_snapshot_formats that
332 # you wish to offer.
333 # To disable system wide have in $GITWEB_CONFIG
334 # $feature{'snapshot'}{'default'} = [];
335 # To have project specific config enable override in $GITWEB_CONFIG
336 # $feature{'snapshot'}{'override'} = 1;
337 # and in project config, a comma-separated list of formats or "none"
338 # to disable. Example: gitweb.snapshot = tbz2,zip;
339 'snapshot' => {
340 'sub' => \&feature_snapshot,
341 'override' => 0,
342 'default' => ['tgz']},
343
344 # Enable text search, which will list the commits which match author,
345 # committer or commit text to a given string. Enabled by default.
346 # Project specific override is not supported.
347 #
348 # Note that this controls all search features, which means that if
349 # it is disabled, then 'grep' and 'pickaxe' search would also be
350 # disabled.
351 'search' => {
352 'override' => 0,
353 'default' => [1]},
354
355 # Enable grep search, which will list the files in currently selected
356 # tree containing the given string. Enabled by default. This can be
357 # potentially CPU-intensive, of course.
358 # Note that you need to have 'search' feature enabled too.
359
360 # To enable system wide have in $GITWEB_CONFIG
361 # $feature{'grep'}{'default'} = [1];
362 # To have project specific config enable override in $GITWEB_CONFIG
363 # $feature{'grep'}{'override'} = 1;
364 # and in project config gitweb.grep = 0|1;
365 'grep' => {
366 'sub' => sub { feature_bool('grep', @_) },
367 'override' => 0,
368 'default' => [1]},
369
370 # Enable the pickaxe search, which will list the commits that modified
371 # a given string in a file. This can be practical and quite faster
372 # alternative to 'blame', but still potentially CPU-intensive.
373 # Note that you need to have 'search' feature enabled too.
374
375 # To enable system wide have in $GITWEB_CONFIG
376 # $feature{'pickaxe'}{'default'} = [1];
377 # To have project specific config enable override in $GITWEB_CONFIG
378 # $feature{'pickaxe'}{'override'} = 1;
379 # and in project config gitweb.pickaxe = 0|1;
380 'pickaxe' => {
381 'sub' => sub { feature_bool('pickaxe', @_) },
382 'override' => 0,
383 'default' => [1]},
384
385 # Enable showing size of blobs in a 'tree' view, in a separate
386 # column, similar to what 'ls -l' does. This cost a bit of IO.
387
388 # To disable system wide have in $GITWEB_CONFIG
389 # $feature{'show-sizes'}{'default'} = [0];
390 # To have project specific config enable override in $GITWEB_CONFIG
391 # $feature{'show-sizes'}{'override'} = 1;
392 # and in project config gitweb.showsizes = 0|1;
393 'show-sizes' => {
394 'sub' => sub { feature_bool('showsizes', @_) },
395 'override' => 0,
396 'default' => [1]},
397
398 # Make gitweb use an alternative format of the URLs which can be
399 # more readable and natural-looking: project name is embedded
400 # directly in the path and the query string contains other
401 # auxiliary information. All gitweb installations recognize
402 # URL in either format; this configures in which formats gitweb
403 # generates links.
404
405 # To enable system wide have in $GITWEB_CONFIG
406 # $feature{'pathinfo'}{'default'} = [1];
407 # Project specific override is not supported.
408
409 # Note that you will need to change the default location of CSS,
410 # favicon, logo and possibly other files to an absolute URL. Also,
411 # if gitweb.cgi serves as your indexfile, you will need to force
412 # $my_uri to contain the script name in your $GITWEB_CONFIG.
413 'pathinfo' => {
414 'override' => 0,
415 'default' => [0]},
416
417 # Make gitweb consider projects in project root subdirectories
418 # to be forks of existing projects. Given project $projname.git,
419 # projects matching $projname/*.git will not be shown in the main
420 # projects list, instead a '+' mark will be added to $projname
421 # there and a 'forks' view will be enabled for the project, listing
422 # all the forks. If project list is taken from a file, forks have
423 # to be listed after the main project.
424
425 # To enable system wide have in $GITWEB_CONFIG
426 # $feature{'forks'}{'default'} = [1];
427 # Project specific override is not supported.
428 'forks' => {
429 'override' => 0,
430 'default' => [0]},
431
432 # Insert custom links to the action bar of all project pages.
433 # This enables you mainly to link to third-party scripts integrating
434 # into gitweb; e.g. git-browser for graphical history representation
435 # or custom web-based repository administration interface.
436
437 # The 'default' value consists of a list of triplets in the form
438 # (label, link, position) where position is the label after which
439 # to insert the link and link is a format string where %n expands
440 # to the project name, %f to the project path within the filesystem,
441 # %h to the current hash (h gitweb parameter) and %b to the current
442 # hash base (hb gitweb parameter); %% expands to %.
443
444 # To enable system wide have in $GITWEB_CONFIG e.g.
445 # $feature{'actions'}{'default'} = [('graphiclog',
446 # '/git-browser/by-commit.html?r=%n', 'summary')];
447 # Project specific override is not supported.
448 'actions' => {
449 'override' => 0,
450 'default' => []},
451
452 # Allow gitweb scan project content tags of project repository,
453 # and display the popular Web 2.0-ish "tag cloud" near the projects
454 # list. Note that this is something COMPLETELY different from the
455 # normal Git tags.
456
457 # gitweb by itself can show existing tags, but it does not handle
458 # tagging itself; you need to do it externally, outside gitweb.
459 # The format is described in git_get_project_ctags() subroutine.
460 # You may want to install the HTML::TagCloud Perl module to get
461 # a pretty tag cloud instead of just a list of tags.
462
463 # To enable system wide have in $GITWEB_CONFIG
464 # $feature{'ctags'}{'default'} = [1];
465 # Project specific override is not supported.
466
467 # In the future whether ctags editing is enabled might depend
468 # on the value, but using 1 should always mean no editing of ctags.
469 'ctags' => {
470 'override' => 0,
471 'default' => [0]},
472
473 # The maximum number of patches in a patchset generated in patch
474 # view. Set this to 0 or undef to disable patch view, or to a
475 # negative number to remove any limit.
476
477 # To disable system wide have in $GITWEB_CONFIG
478 # $feature{'patches'}{'default'} = [0];
479 # To have project specific config enable override in $GITWEB_CONFIG
480 # $feature{'patches'}{'override'} = 1;
481 # and in project config gitweb.patches = 0|n;
482 # where n is the maximum number of patches allowed in a patchset.
483 'patches' => {
484 'sub' => \&feature_patches,
485 'override' => 0,
486 'default' => [16]},
487
488 # Avatar support. When this feature is enabled, views such as
489 # shortlog or commit will display an avatar associated with
490 # the email of the committer(s) and/or author(s).
491
492 # Currently available providers are gravatar and picon.
493 # If an unknown provider is specified, the feature is disabled.
494
495 # Picon currently relies on the indiana.edu database.
496
497 # To enable system wide have in $GITWEB_CONFIG
498 # $feature{'avatar'}{'default'} = ['<provider>'];
499 # where <provider> is either gravatar or picon.
500 # To have project specific config enable override in $GITWEB_CONFIG
501 # $feature{'avatar'}{'override'} = 1;
502 # and in project config gitweb.avatar = <provider>;
503 'avatar' => {
504 'sub' => \&feature_avatar,
505 'override' => 0,
506 'default' => ['']},
507
508 # Enable displaying how much time and how many git commands
509 # it took to generate and display page. Disabled by default.
510 # Project specific override is not supported.
511 'timed' => {
512 'override' => 0,
513 'default' => [0]},
514
515 # Enable turning some links into links to actions which require
516 # JavaScript to run (like 'blame_incremental'). Not enabled by
517 # default. Project specific override is currently not supported.
518 'javascript-actions' => {
519 'override' => 0,
520 'default' => [0]},
521
522 # Enable and configure ability to change common timezone for dates
523 # in gitweb output via JavaScript. Enabled by default.
524 # Project specific override is not supported.
525 'javascript-timezone' => {
526 'override' => 0,
527 'default' => [
528 'local', # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
529 # or undef to turn off this feature
530 'gitweb_tz', # name of cookie where to store selected timezone
531 'datetime', # CSS class used to mark up dates for manipulation
532 ]},
533
534 # Syntax highlighting support. This is based on Daniel Svensson's
535 # and Sham Chukoury's work in gitweb-xmms2.git.
536 # It requires the 'highlight' program present in $PATH,
537 # and therefore is disabled by default.
538
539 # To enable system wide have in $GITWEB_CONFIG
540 # $feature{'highlight'}{'default'} = [1];
541
542 'highlight' => {
543 'sub' => sub { feature_bool('highlight', @_) },
544 'override' => 0,
545 'default' => [0]},
546
547 # Enable displaying of remote heads in the heads list
548
549 # To enable system wide have in $GITWEB_CONFIG
550 # $feature{'remote_heads'}{'default'} = [1];
551 # To have project specific config enable override in $GITWEB_CONFIG
552 # $feature{'remote_heads'}{'override'} = 1;
553 # and in project config gitweb.remoteheads = 0|1;
554 'remote_heads' => {
555 'sub' => sub { feature_bool('remote_heads', @_) },
556 'override' => 0,
557 'default' => [0]},
558
559 # Enable showing branches under other refs in addition to heads
560
561 # To set system wide extra branch refs have in $GITWEB_CONFIG
562 # $feature{'extra-branch-refs'}{'default'} = ['dirs', 'of', 'choice'];
563 # To have project specific config enable override in $GITWEB_CONFIG
564 # $feature{'extra-branch-refs'}{'override'} = 1;
565 # and in project config gitweb.extrabranchrefs = dirs of choice
566 # Every directory is separated with whitespace.
567
568 'extra-branch-refs' => {
569 'sub' => \&feature_extra_branch_refs,
570 'override' => 0,
571 'default' => []},
572
573 # Redact e-mail addresses.
574
575 # To enable system wide have in $GITWEB_CONFIG
576 # $feature{'email-privacy'}{'default'} = [1];
577 'email-privacy' => {
578 'sub' => sub { feature_bool('email-privacy', @_) },
579 'override' => 1,
580 'default' => [0]},
581 );
582
583 sub gitweb_get_feature {
584 my ($name) = @_;
585 return unless exists $feature{$name};
586 my ($sub, $override, @defaults) = (
587 $feature{$name}{'sub'},
588 $feature{$name}{'override'},
589 @{$feature{$name}{'default'}});
590 # project specific override is possible only if we have project
591 our $git_dir; # global variable, declared later
592 if (!$override || !defined $git_dir) {
593 return @defaults;
594 }
595 if (!defined $sub) {
596 warn "feature $name is not overridable";
597 return @defaults;
598 }
599 return $sub->(@defaults);
600 }
601
602 # A wrapper to check if a given feature is enabled.
603 # With this, you can say
604 #
605 # my $bool_feat = gitweb_check_feature('bool_feat');
606 # gitweb_check_feature('bool_feat') or somecode;
607 #
608 # instead of
609 #
610 # my ($bool_feat) = gitweb_get_feature('bool_feat');
611 # (gitweb_get_feature('bool_feat'))[0] or somecode;
612 #
613 sub gitweb_check_feature {
614 return (gitweb_get_feature(@_))[0];
615 }
616
617
618 sub feature_bool {
619 my $key = shift;
620 my ($val) = git_get_project_config($key, '--bool');
621
622 if (!defined $val) {
623 return ($_[0]);
624 } elsif ($val eq 'true') {
625 return (1);
626 } elsif ($val eq 'false') {
627 return (0);
628 }
629 }
630
631 sub feature_snapshot {
632 my (@fmts) = @_;
633
634 my ($val) = git_get_project_config('snapshot');
635
636 if ($val) {
637 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
638 }
639
640 return @fmts;
641 }
642
643 sub feature_patches {
644 my @val = (git_get_project_config('patches', '--int'));
645
646 if (@val) {
647 return @val;
648 }
649
650 return ($_[0]);
651 }
652
653 sub feature_avatar {
654 my @val = (git_get_project_config('avatar'));
655
656 return @val ? @val : @_;
657 }
658
659 sub feature_extra_branch_refs {
660 my (@branch_refs) = @_;
661 my $values = git_get_project_config('extrabranchrefs');
662
663 if ($values) {
664 $values = config_to_multi ($values);
665 @branch_refs = ();
666 foreach my $value (@{$values}) {
667 push @branch_refs, split /\s+/, $value;
668 }
669 }
670
671 return @branch_refs;
672 }
673
674 # checking HEAD file with -e is fragile if the repository was
675 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
676 # and then pruned.
677 sub check_head_link {
678 my ($dir) = @_;
679 my $headfile = "$dir/HEAD";
680 return ((-e $headfile) ||
681 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
682 }
683
684 sub check_export_ok {
685 my ($dir) = @_;
686 return (check_head_link($dir) &&
687 (!$export_ok || -e "$dir/$export_ok") &&
688 (!$export_auth_hook || $export_auth_hook->($dir)));
689 }
690
691 # process alternate names for backward compatibility
692 # filter out unsupported (unknown) snapshot formats
693 sub filter_snapshot_fmts {
694 my @fmts = @_;
695
696 @fmts = map {
697 exists $known_snapshot_format_aliases{$_} ?
698 $known_snapshot_format_aliases{$_} : $_} @fmts;
699 @fmts = grep {
700 exists $known_snapshot_formats{$_} &&
701 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
702 }
703
704 sub filter_and_validate_refs {
705 my @refs = @_;
706 my %unique_refs = ();
707
708 foreach my $ref (@refs) {
709 die_error(500, "Invalid ref '$ref' in 'extra-branch-refs' feature") unless (is_valid_ref_format($ref));
710 # 'heads' are added implicitly in get_branch_refs().
711 $unique_refs{$ref} = 1 if ($ref ne 'heads');
712 }
713 return sort keys %unique_refs;
714 }
715
716 # If it is set to code reference, it is code that it is to be run once per
717 # request, allowing updating configurations that change with each request,
718 # while running other code in config file only once.
719 #
720 # Otherwise, if it is false then gitweb would process config file only once;
721 # if it is true then gitweb config would be run for each request.
722 our $per_request_config = 1;
723
724 # read and parse gitweb config file given by its parameter.
725 # returns true on success, false on recoverable error, allowing
726 # to chain this subroutine, using first file that exists.
727 # dies on errors during parsing config file, as it is unrecoverable.
728 sub read_config_file {
729 my $filename = shift;
730 return unless defined $filename;
731 # die if there are errors parsing config file
732 if (-e $filename) {
733 do $filename;
734 die $@ if $@;
735 return 1;
736 }
737 return;
738 }
739
740 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
741 sub evaluate_gitweb_config {
742 our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "gitweb_config.perl";
743 our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "/etc/gitweb.conf";
744 our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "/etc/gitweb-common.conf";
745
746 # Protect against duplications of file names, to not read config twice.
747 # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
748 # there possibility of duplication of filename there doesn't matter.
749 $GITWEB_CONFIG = "" if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
750 $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
751
752 # Common system-wide settings for convenience.
753 # Those settings can be overridden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
754 read_config_file($GITWEB_CONFIG_COMMON);
755
756 # Use first config file that exists. This means use the per-instance
757 # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
758 read_config_file($GITWEB_CONFIG) and return;
759 read_config_file($GITWEB_CONFIG_SYSTEM);
760 }
761
762 # Get loadavg of system, to compare against $maxload.
763 # Currently it requires '/proc/loadavg' present to get loadavg;
764 # if it is not present it returns 0, which means no load checking.
765 sub get_loadavg {
766 if( -e '/proc/loadavg' ){
767 open my $fd, '<', '/proc/loadavg'
768 or return 0;
769 my @load = split(/\s+/, scalar <$fd>);
770 close $fd;
771
772 # The first three columns measure CPU and IO utilization of the last one,
773 # five, and 10 minute periods. The fourth column shows the number of
774 # currently running processes and the total number of processes in the m/n
775 # format. The last column displays the last process ID used.
776 return $load[0] || 0;
777 }
778 # additional checks for load average should go here for things that don't export
779 # /proc/loadavg
780
781 return 0;
782 }
783
784 # version of the core git binary
785 our $git_version;
786 sub evaluate_git_version {
787 our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
788 $number_of_git_cmds++;
789 }
790
791 sub check_loadavg {
792 if (defined $maxload && get_loadavg() > $maxload) {
793 die_error(503, "The load average on the server is too high");
794 }
795 }
796
797 # ======================================================================
798 # input validation and dispatch
799
800 # Various hash size-related values.
801 my $sha1_len = 40;
802 my $sha256_extra_len = 24;
803 my $sha256_len = $sha1_len + $sha256_extra_len;
804
805 # A regex matching $len hex characters. $len may be a range (e.g. 7,64).
806 sub oid_nlen_regex {
807 my $len = shift;
808 my $hchr = qr/[0-9a-fA-F]/;
809 return qr/(?:(?:$hchr){$len})/;
810 }
811
812 # A regex matching two sets of $nlen hex characters, prefixed by the literal
813 # string $prefix and with the literal string $infix between them.
814 sub oid_nlen_prefix_infix_regex {
815 my $nlen = shift;
816 my $prefix = shift;
817 my $infix = shift;
818
819 my $rx = oid_nlen_regex($nlen);
820
821 return qr/^\Q$prefix\E$rx\Q$infix\E$rx$/;
822 }
823
824 # A regex matching a valid object ID.
825 our $oid_regex;
826 {
827 my $x = oid_nlen_regex($sha1_len);
828 my $y = oid_nlen_regex($sha256_extra_len);
829 $oid_regex = qr/(?:$x(?:$y)?)/;
830 }
831
832 # input parameters can be collected from a variety of sources (presently, CGI
833 # and PATH_INFO), so we define an %input_params hash that collects them all
834 # together during validation: this allows subsequent uses (e.g. href()) to be
835 # agnostic of the parameter origin
836
837 our %input_params = ();
838
839 # input parameters are stored with the long parameter name as key. This will
840 # also be used in the href subroutine to convert parameters to their CGI
841 # equivalent, and since the href() usage is the most frequent one, we store
842 # the name -> CGI key mapping here, instead of the reverse.
843 #
844 # XXX: Warning: If you touch this, check the search form for updating,
845 # too.
846
847 our @cgi_param_mapping = (
848 project => "p",
849 action => "a",
850 file_name => "f",
851 file_parent => "fp",
852 hash => "h",
853 hash_parent => "hp",
854 hash_base => "hb",
855 hash_parent_base => "hpb",
856 page => "pg",
857 order => "o",
858 searchtext => "s",
859 searchtype => "st",
860 snapshot_format => "sf",
861 extra_options => "opt",
862 search_use_regexp => "sr",
863 ctag => "by_tag",
864 diff_style => "ds",
865 project_filter => "pf",
866 # this must be last entry (for manipulation from JavaScript)
867 javascript => "js"
868 );
869 our %cgi_param_mapping = @cgi_param_mapping;
870
871 # we will also need to know the possible actions, for validation
872 our %actions = (
873 "blame" => \&git_blame,
874 "blame_incremental" => \&git_blame_incremental,
875 "blame_data" => \&git_blame_data,
876 "blobdiff" => \&git_blobdiff,
877 "blobdiff_plain" => \&git_blobdiff_plain,
878 "blob" => \&git_blob,
879 "blob_plain" => \&git_blob_plain,
880 "commitdiff" => \&git_commitdiff,
881 "commitdiff_plain" => \&git_commitdiff_plain,
882 "commit" => \&git_commit,
883 "forks" => \&git_forks,
884 "heads" => \&git_heads,
885 "history" => \&git_history,
886 "log" => \&git_log,
887 "patch" => \&git_patch,
888 "patches" => \&git_patches,
889 "remotes" => \&git_remotes,
890 "atom" => \&git_atom,
891 "search" => \&git_search,
892 "search_help" => \&git_search_help,
893 "shortlog" => \&git_shortlog,
894 "summary" => \&git_summary,
895 "tag" => \&git_tag,
896 "tags" => \&git_tags,
897 "tree" => \&git_tree,
898 "snapshot" => \&git_snapshot,
899 "object" => \&git_object,
900 # those below don't need $project
901 "opml" => \&git_opml,
902 "project_list" => \&git_project_list,
903 "project_index" => \&git_project_index,
904 );
905
906 # finally, we have the hash of allowed extra_options for the commands that
907 # allow them
908 our %allowed_options = (
909 "--no-merges" => [ qw(atom log shortlog history) ],
910 );
911
912 # fill %input_params with the CGI parameters. All values except for 'opt'
913 # should be single values, but opt can be an array. We should probably
914 # build an array of parameters that can be multi-valued, but since for the time
915 # being it's only this one, we just single it out
916 sub evaluate_query_params {
917 our $cgi;
918
919 while (my ($name, $symbol) = each %cgi_param_mapping) {
920 if ($symbol eq 'opt') {
921 $input_params{$name} = [ map { decode_utf8($_) } $cgi->multi_param($symbol) ];
922 } else {
923 $input_params{$name} = decode_utf8($cgi->param($symbol));
924 }
925 }
926 }
927
928 # now read PATH_INFO and update the parameter list for missing parameters
929 sub evaluate_path_info {
930 return if defined $input_params{'project'};
931 return if !$path_info;
932 $path_info =~ s,^/+,,;
933 return if !$path_info;
934
935 # find which part of PATH_INFO is project
936 my $project = $path_info;
937 $project =~ s,/+$,,;
938 while ($project && !check_head_link("$projectroot/$project")) {
939 $project =~ s,/*[^/]*$,,;
940 }
941 return unless $project;
942 $input_params{'project'} = $project;
943
944 # do not change any parameters if an action is given using the query string
945 return if $input_params{'action'};
946 $path_info =~ s,^\Q$project\E/*,,;
947
948 # next, check if we have an action
949 my $action = $path_info;
950 $action =~ s,/.*$,,;
951 if (exists $actions{$action}) {
952 $path_info =~ s,^$action/*,,;
953 $input_params{'action'} = $action;
954 }
955
956 # list of actions that want hash_base instead of hash, but can have no
957 # pathname (f) parameter
958 my @wants_base = (
959 'tree',
960 'history',
961 );
962
963 # we want to catch, among others
964 # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
965 my ($parentrefname, $parentpathname, $refname, $pathname) =
966 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
967
968 # first, analyze the 'current' part
969 if (defined $pathname) {
970 # we got "branch:filename" or "branch:dir/"
971 # we could use git_get_type(branch:pathname), but:
972 # - it needs $git_dir
973 # - it does a git() call
974 # - the convention of terminating directories with a slash
975 # makes it superfluous
976 # - embedding the action in the PATH_INFO would make it even
977 # more superfluous
978 $pathname =~ s,^/+,,;
979 if (!$pathname || substr($pathname, -1) eq "/") {
980 $input_params{'action'} ||= "tree";
981 $pathname =~ s,/$,,;
982 } else {
983 # the default action depends on whether we had parent info
984 # or not
985 if ($parentrefname) {
986 $input_params{'action'} ||= "blobdiff_plain";
987 } else {
988 $input_params{'action'} ||= "blob_plain";
989 }
990 }
991 $input_params{'hash_base'} ||= $refname;
992 $input_params{'file_name'} ||= $pathname;
993 } elsif (defined $refname) {
994 # we got "branch". In this case we have to choose if we have to
995 # set hash or hash_base.
996 #
997 # Most of the actions without a pathname only want hash to be
998 # set, except for the ones specified in @wants_base that want
999 # hash_base instead. It should also be noted that hand-crafted
1000 # links having 'history' as an action and no pathname or hash
1001 # set will fail, but that happens regardless of PATH_INFO.
1002 if (defined $parentrefname) {
1003 # if there is parent let the default be 'shortlog' action
1004 # (for http://git.example.com/repo.git/A..B links); if there
1005 # is no parent, dispatch will detect type of object and set
1006 # action appropriately if required (if action is not set)
1007 $input_params{'action'} ||= "shortlog";
1008 }
1009 if ($input_params{'action'} &&
1010 grep { $_ eq $input_params{'action'} } @wants_base) {
1011 $input_params{'hash_base'} ||= $refname;
1012 } else {
1013 $input_params{'hash'} ||= $refname;
1014 }
1015 }
1016
1017 # next, handle the 'parent' part, if present
1018 if (defined $parentrefname) {
1019 # a missing pathspec defaults to the 'current' filename, allowing e.g.
1020 # someproject/blobdiff/oldrev..newrev:/filename
1021 if ($parentpathname) {
1022 $parentpathname =~ s,^/+,,;
1023 $parentpathname =~ s,/$,,;
1024 $input_params{'file_parent'} ||= $parentpathname;
1025 } else {
1026 $input_params{'file_parent'} ||= $input_params{'file_name'};
1027 }
1028 # we assume that hash_parent_base is wanted if a path was specified,
1029 # or if the action wants hash_base instead of hash
1030 if (defined $input_params{'file_parent'} ||
1031 grep { $_ eq $input_params{'action'} } @wants_base) {
1032 $input_params{'hash_parent_base'} ||= $parentrefname;
1033 } else {
1034 $input_params{'hash_parent'} ||= $parentrefname;
1035 }
1036 }
1037
1038 # for the snapshot action, we allow URLs in the form
1039 # $project/snapshot/$hash.ext
1040 # where .ext determines the snapshot and gets removed from the
1041 # passed $refname to provide the $hash.
1042 #
1043 # To be able to tell that $refname includes the format extension, we
1044 # require the following two conditions to be satisfied:
1045 # - the hash input parameter MUST have been set from the $refname part
1046 # of the URL (i.e. they must be equal)
1047 # - the snapshot format MUST NOT have been defined already (e.g. from
1048 # CGI parameter sf)
1049 # It's also useless to try any matching unless $refname has a dot,
1050 # so we check for that too
1051 if (defined $input_params{'action'} &&
1052 $input_params{'action'} eq 'snapshot' &&
1053 defined $refname && index($refname, '.') != -1 &&
1054 $refname eq $input_params{'hash'} &&
1055 !defined $input_params{'snapshot_format'}) {
1056 # We loop over the known snapshot formats, checking for
1057 # extensions. Allowed extensions are both the defined suffix
1058 # (which includes the initial dot already) and the snapshot
1059 # format key itself, with a prepended dot
1060 while (my ($fmt, $opt) = each %known_snapshot_formats) {
1061 my $hash = $refname;
1062 unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
1063 next;
1064 }
1065 my $sfx = $1;
1066 # a valid suffix was found, so set the snapshot format
1067 # and reset the hash parameter
1068 $input_params{'snapshot_format'} = $fmt;
1069 $input_params{'hash'} = $hash;
1070 # we also set the format suffix to the one requested
1071 # in the URL: this way a request for e.g. .tgz returns
1072 # a .tgz instead of a .tar.gz
1073 $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
1074 last;
1075 }
1076 }
1077 }
1078
1079 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
1080 $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
1081 $searchtext, $search_regexp, $project_filter);
1082 sub evaluate_and_validate_params {
1083 our $action = $input_params{'action'};
1084 if (defined $action) {
1085 if (!is_valid_action($action)) {
1086 die_error(400, "Invalid action parameter");
1087 }
1088 }
1089
1090 # parameters which are pathnames
1091 our $project = $input_params{'project'};
1092 if (defined $project) {
1093 if (!is_valid_project($project)) {
1094 undef $project;
1095 die_error(404, "No such project");
1096 }
1097 }
1098
1099 our $project_filter = $input_params{'project_filter'};
1100 if (defined $project_filter) {
1101 if (!is_valid_pathname($project_filter)) {
1102 die_error(404, "Invalid project_filter parameter");
1103 }
1104 }
1105
1106 our $file_name = $input_params{'file_name'};
1107 if (defined $file_name) {
1108 if (!is_valid_pathname($file_name)) {
1109 die_error(400, "Invalid file parameter");
1110 }
1111 }
1112
1113 our $file_parent = $input_params{'file_parent'};
1114 if (defined $file_parent) {
1115 if (!is_valid_pathname($file_parent)) {
1116 die_error(400, "Invalid file parent parameter");
1117 }
1118 }
1119
1120 # parameters which are refnames
1121 our $hash = $input_params{'hash'};
1122 if (defined $hash) {
1123 if (!is_valid_refname($hash)) {
1124 die_error(400, "Invalid hash parameter");
1125 }
1126 }
1127
1128 our $hash_parent = $input_params{'hash_parent'};
1129 if (defined $hash_parent) {
1130 if (!is_valid_refname($hash_parent)) {
1131 die_error(400, "Invalid hash parent parameter");
1132 }
1133 }
1134
1135 our $hash_base = $input_params{'hash_base'};
1136 if (defined $hash_base) {
1137 if (!is_valid_refname($hash_base)) {
1138 die_error(400, "Invalid hash base parameter");
1139 }
1140 }
1141
1142 our @extra_options = @{$input_params{'extra_options'}};
1143 # @extra_options is always defined, since it can only be (currently) set from
1144 # CGI, and $cgi->param() returns the empty array in array context if the param
1145 # is not set
1146 foreach my $opt (@extra_options) {
1147 if (not exists $allowed_options{$opt}) {
1148 die_error(400, "Invalid option parameter");
1149 }
1150 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1151 die_error(400, "Invalid option parameter for this action");
1152 }
1153 }
1154
1155 our $hash_parent_base = $input_params{'hash_parent_base'};
1156 if (defined $hash_parent_base) {
1157 if (!is_valid_refname($hash_parent_base)) {
1158 die_error(400, "Invalid hash parent base parameter");
1159 }
1160 }
1161
1162 # other parameters
1163 our $page = $input_params{'page'};
1164 if (defined $page) {
1165 if ($page =~ m/[^0-9]/) {
1166 die_error(400, "Invalid page parameter");
1167 }
1168 }
1169
1170 our $searchtype = $input_params{'searchtype'};
1171 if (defined $searchtype) {
1172 if ($searchtype =~ m/[^a-z]/) {
1173 die_error(400, "Invalid searchtype parameter");
1174 }
1175 }
1176
1177 our $search_use_regexp = $input_params{'search_use_regexp'};
1178
1179 our $searchtext = $input_params{'searchtext'};
1180 our $search_regexp = undef;
1181 if (defined $searchtext) {
1182 if (length($searchtext) < 2) {
1183 die_error(403, "At least two characters are required for search parameter");
1184 }
1185 if ($search_use_regexp) {
1186 $search_regexp = $searchtext;
1187 if (!eval { qr/$search_regexp/; 1; }) {
1188 (my $error = $@) =~ s/ at \S+ line \d+.*\n?//;
1189 die_error(400, "Invalid search regexp '$search_regexp'",
1190 esc_html($error));
1191 }
1192 } else {
1193 $search_regexp = quotemeta $searchtext;
1194 }
1195 }
1196 }
1197
1198 # path to the current git repository
1199 our $git_dir;
1200 sub evaluate_git_dir {
1201 our $git_dir = "$projectroot/$project" if $project;
1202 }
1203
1204 our (@snapshot_fmts, $git_avatar, @extra_branch_refs);
1205 sub configure_gitweb_features {
1206 # list of supported snapshot formats
1207 our @snapshot_fmts = gitweb_get_feature('snapshot');
1208 @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1209
1210 our ($git_avatar) = gitweb_get_feature('avatar');
1211 $git_avatar = '' unless $git_avatar =~ /^(?:gravatar|picon)$/s;
1212
1213 our @extra_branch_refs = gitweb_get_feature('extra-branch-refs');
1214 @extra_branch_refs = filter_and_validate_refs (@extra_branch_refs);
1215 }
1216
1217 sub get_branch_refs {
1218 return ('heads', @extra_branch_refs);
1219 }
1220
1221 # custom error handler: 'die <message>' is Internal Server Error
1222 sub handle_errors_html {
1223 my $msg = shift; # it is already HTML escaped
1224
1225 # to avoid infinite loop where error occurs in die_error,
1226 # change handler to default handler, disabling handle_errors_html
1227 set_message("Error occurred when inside die_error:\n$msg");
1228
1229 # you cannot jump out of die_error when called as error handler;
1230 # the subroutine set via CGI::Carp::set_message is called _after_
1231 # HTTP headers are already written, so it cannot write them itself
1232 die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1233 }
1234 set_message(\&handle_errors_html);
1235
1236 # dispatch
1237 sub dispatch {
1238 if (!defined $action) {
1239 if (defined $hash) {
1240 $action = git_get_type($hash);
1241 $action or die_error(404, "Object does not exist");
1242 } elsif (defined $hash_base && defined $file_name) {
1243 $action = git_get_type("$hash_base:$file_name");
1244 $action or die_error(404, "File or directory does not exist");
1245 } elsif (defined $project) {
1246 $action = 'summary';
1247 } else {
1248 $action = 'project_list';
1249 }
1250 }
1251 if (!defined($actions{$action})) {
1252 die_error(400, "Unknown action");
1253 }
1254 if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1255 !$project) {
1256 die_error(400, "Project needed");
1257 }
1258 $actions{$action}->();
1259 }
1260
1261 sub reset_timer {
1262 our $t0 = [ gettimeofday() ]
1263 if defined $t0;
1264 our $number_of_git_cmds = 0;
1265 }
1266
1267 our $first_request = 1;
1268 sub run_request {
1269 reset_timer();
1270
1271 evaluate_uri();
1272 if ($first_request) {
1273 evaluate_gitweb_config();
1274 evaluate_git_version();
1275 }
1276 if ($per_request_config) {
1277 if (ref($per_request_config) eq 'CODE') {
1278 $per_request_config->();
1279 } elsif (!$first_request) {
1280 evaluate_gitweb_config();
1281 }
1282 }
1283 check_loadavg();
1284
1285 # $projectroot and $projects_list might be set in gitweb config file
1286 $projects_list ||= $projectroot;
1287
1288 evaluate_query_params();
1289 evaluate_path_info();
1290 evaluate_and_validate_params();
1291 evaluate_git_dir();
1292
1293 configure_gitweb_features();
1294
1295 dispatch();
1296 }
1297
1298 our $is_last_request = sub { 1 };
1299 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1300 our $CGI = 'CGI';
1301 our $cgi;
1302 our $FCGI_Stream_PRINT_raw = \&FCGI::Stream::PRINT;
1303 sub configure_as_fcgi {
1304 require CGI::Fast;
1305 our $CGI = 'CGI::Fast';
1306 # FCGI is not Unicode aware hence the UTF-8 encoding must be done manually.
1307 # However no encoding must be done within git_blob_plain() and git_snapshot()
1308 # which must still output in raw binary mode.
1309 no warnings 'redefine';
1310 my $enc = Encode::find_encoding('UTF-8');
1311 *FCGI::Stream::PRINT = sub {
1312 my @OUTPUT = @_;
1313 for (my $i = 1; $i < @_; $i++) {
1314 $OUTPUT[$i] = $enc->encode($_[$i], Encode::FB_CROAK|Encode::LEAVE_SRC);
1315 }
1316 @_ = @OUTPUT;
1317 goto $FCGI_Stream_PRINT_raw;
1318 };
1319
1320 my $request_number = 0;
1321 # let each child service 100 requests
1322 our $is_last_request = sub { ++$request_number > 100 };
1323 }
1324 sub evaluate_argv {
1325 my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1326 configure_as_fcgi()
1327 if $script_name =~ /\.fcgi$/;
1328
1329 return unless (@ARGV);
1330
1331 require Getopt::Long;
1332 Getopt::Long::GetOptions(
1333 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1334 'nproc|n=i' => sub {
1335 my ($arg, $val) = @_;
1336 return unless eval { require FCGI::ProcManager; 1; };
1337 my $proc_manager = FCGI::ProcManager->new({
1338 n_processes => $val,
1339 });
1340 our $pre_listen_hook = sub { $proc_manager->pm_manage() };
1341 our $pre_dispatch_hook = sub { $proc_manager->pm_pre_dispatch() };
1342 our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1343 },
1344 );
1345 }
1346
1347 sub run {
1348 evaluate_argv();
1349
1350 $first_request = 1;
1351 $pre_listen_hook->()
1352 if $pre_listen_hook;
1353
1354 REQUEST:
1355 while ($cgi = $CGI->new()) {
1356 $pre_dispatch_hook->()
1357 if $pre_dispatch_hook;
1358
1359 run_request();
1360
1361 $post_dispatch_hook->()
1362 if $post_dispatch_hook;
1363 $first_request = 0;
1364
1365 last REQUEST if ($is_last_request->());
1366 }
1367
1368 DONE_GITWEB:
1369 1;
1370 }
1371
1372 run();
1373
1374 if (defined caller) {
1375 # wrapped in a subroutine processing requests,
1376 # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1377 return;
1378 } else {
1379 # pure CGI script, serving single request
1380 exit;
1381 }
1382
1383 ## ======================================================================
1384 ## action links
1385
1386 # possible values of extra options
1387 # -full => 0|1 - use absolute/full URL ($my_uri/$my_url as base)
1388 # -replay => 1 - start from a current view (replay with modifications)
1389 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1390 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1391 sub href {
1392 my %params = @_;
1393 # default is to use -absolute url() i.e. $my_uri
1394 my $href = $params{-full} ? $my_url : $my_uri;
1395
1396 # implicit -replay, must be first of implicit params
1397 $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1398
1399 $params{'project'} = $project unless exists $params{'project'};
1400
1401 if ($params{-replay}) {
1402 while (my ($name, $symbol) = each %cgi_param_mapping) {
1403 if (!exists $params{$name}) {
1404 $params{$name} = $input_params{$name};
1405 }
1406 }
1407 }
1408
1409 my $use_pathinfo = gitweb_check_feature('pathinfo');
1410 if (defined $params{'project'} &&
1411 (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1412 # try to put as many parameters as possible in PATH_INFO:
1413 # - project name
1414 # - action
1415 # - hash_parent or hash_parent_base:/file_parent
1416 # - hash or hash_base:/filename
1417 # - the snapshot_format as an appropriate suffix
1418
1419 # When the script is the root DirectoryIndex for the domain,
1420 # $href here would be something like http://gitweb.example.com/
1421 # Thus, we strip any trailing / from $href, to spare us double
1422 # slashes in the final URL
1423 $href =~ s,/$,,;
1424
1425 # Then add the project name, if present
1426 $href .= "/".esc_path_info($params{'project'});
1427 delete $params{'project'};
1428
1429 # since we destructively absorb parameters, we keep this
1430 # boolean that remembers if we're handling a snapshot
1431 my $is_snapshot = $params{'action'} eq 'snapshot';
1432
1433 # Summary just uses the project path URL, any other action is
1434 # added to the URL
1435 if (defined $params{'action'}) {
1436 $href .= "/".esc_path_info($params{'action'})
1437 unless $params{'action'} eq 'summary';
1438 delete $params{'action'};
1439 }
1440
1441 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1442 # stripping nonexistent or useless pieces
1443 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1444 || $params{'hash_parent'} || $params{'hash'});
1445 if (defined $params{'hash_base'}) {
1446 if (defined $params{'hash_parent_base'}) {
1447 $href .= esc_path_info($params{'hash_parent_base'});
1448 # skip the file_parent if it's the same as the file_name
1449 if (defined $params{'file_parent'}) {
1450 if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1451 delete $params{'file_parent'};
1452 } elsif ($params{'file_parent'} !~ /\.\./) {
1453 $href .= ":/".esc_path_info($params{'file_parent'});
1454 delete $params{'file_parent'};
1455 }
1456 }
1457 $href .= "..";
1458 delete $params{'hash_parent'};
1459 delete $params{'hash_parent_base'};
1460 } elsif (defined $params{'hash_parent'}) {
1461 $href .= esc_path_info($params{'hash_parent'}). "..";
1462 delete $params{'hash_parent'};
1463 }
1464
1465 $href .= esc_path_info($params{'hash_base'});
1466 if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1467 $href .= ":/".esc_path_info($params{'file_name'});
1468 delete $params{'file_name'};
1469 }
1470 delete $params{'hash'};
1471 delete $params{'hash_base'};
1472 } elsif (defined $params{'hash'}) {
1473 $href .= esc_path_info($params{'hash'});
1474 delete $params{'hash'};
1475 }
1476
1477 # If the action was a snapshot, we can absorb the
1478 # snapshot_format parameter too
1479 if ($is_snapshot) {
1480 my $fmt = $params{'snapshot_format'};
1481 # snapshot_format should always be defined when href()
1482 # is called, but just in case some code forgets, we
1483 # fall back to the default
1484 $fmt ||= $snapshot_fmts[0];
1485 $href .= $known_snapshot_formats{$fmt}{'suffix'};
1486 delete $params{'snapshot_format'};
1487 }
1488 }
1489
1490 # now encode the parameters explicitly
1491 my @result = ();
1492 for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1493 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1494 if (defined $params{$name}) {
1495 if (ref($params{$name}) eq "ARRAY") {
1496 foreach my $par (@{$params{$name}}) {
1497 push @result, $symbol . "=" . esc_param($par);
1498 }
1499 } else {
1500 push @result, $symbol . "=" . esc_param($params{$name});
1501 }
1502 }
1503 }
1504 $href .= "?" . join(';', @result) if scalar @result;
1505
1506 # final transformation: trailing spaces must be escaped (URI-encoded)
1507 $href =~ s/(\s+)$/CGI::escape($1)/e;
1508
1509 if ($params{-anchor}) {
1510 $href .= "#".esc_param($params{-anchor});
1511 }
1512
1513 return $href;
1514 }
1515
1516
1517 ## ======================================================================
1518 ## validation, quoting/unquoting and escaping
1519
1520 sub is_valid_action {
1521 my $input = shift;
1522 return undef unless exists $actions{$input};
1523 return 1;
1524 }
1525
1526 sub is_valid_project {
1527 my $input = shift;
1528
1529 return unless defined $input;
1530 if (!is_valid_pathname($input) ||
1531 !(-d "$projectroot/$input") ||
1532 !check_export_ok("$projectroot/$input") ||
1533 ($strict_export && !project_in_list($input))) {
1534 return undef;
1535 } else {
1536 return 1;
1537 }
1538 }
1539
1540 sub is_valid_pathname {
1541 my $input = shift;
1542
1543 return undef unless defined $input;
1544 # no '.' or '..' as elements of path, i.e. no '.' or '..'
1545 # at the beginning, at the end, and between slashes.
1546 # also this catches doubled slashes
1547 if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1548 return undef;
1549 }
1550 # no null characters
1551 if ($input =~ m!\0!) {
1552 return undef;
1553 }
1554 return 1;
1555 }
1556
1557 sub is_valid_ref_format {
1558 my $input = shift;
1559
1560 return undef unless defined $input;
1561 # restrictions on ref name according to git-check-ref-format
1562 if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1563 return undef;
1564 }
1565 return 1;
1566 }
1567
1568 sub is_valid_refname {
1569 my $input = shift;
1570
1571 return undef unless defined $input;
1572 # textual hashes are O.K.
1573 if ($input =~ m/^$oid_regex$/) {
1574 return 1;
1575 }
1576 # it must be correct pathname
1577 is_valid_pathname($input) or return undef;
1578 # check git-check-ref-format restrictions
1579 is_valid_ref_format($input) or return undef;
1580 return 1;
1581 }
1582
1583 # decode sequences of octets in utf8 into Perl's internal form,
1584 # which is utf-8 with utf8 flag set if needed. gitweb writes out
1585 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1586 sub to_utf8 {
1587 my $str = shift;
1588 return undef unless defined $str;
1589
1590 if (utf8::is_utf8($str) || utf8::decode($str)) {
1591 return $str;
1592 } else {
1593 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1594 }
1595 }
1596
1597 # quote unsafe chars, but keep the slash, even when it's not
1598 # correct, but quoted slashes look too horrible in bookmarks
1599 sub esc_param {
1600 my $str = shift;
1601 return undef unless defined $str;
1602 $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1603 $str =~ s/ /\+/g;
1604 return $str;
1605 }
1606
1607 # the quoting rules for path_info fragment are slightly different
1608 sub esc_path_info {
1609 my $str = shift;
1610 return undef unless defined $str;
1611
1612 # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1613 $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1614
1615 return $str;
1616 }
1617
1618 # quote unsafe chars in whole URL, so some characters cannot be quoted
1619 sub esc_url {
1620 my $str = shift;
1621 return undef unless defined $str;
1622 $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1623 $str =~ s/ /\+/g;
1624 return $str;
1625 }
1626
1627 # quote unsafe characters in HTML attributes
1628 sub esc_attr {
1629
1630 # for XHTML conformance escaping '"' to '&quot;' is not enough
1631 return esc_html(@_);
1632 }
1633
1634 # replace invalid utf8 character with SUBSTITUTION sequence
1635 sub esc_html {
1636 my $str = shift;
1637 my %opts = @_;
1638
1639 return undef unless defined $str;
1640
1641 $str = to_utf8($str);
1642 $str = $cgi->escapeHTML($str);
1643 if ($opts{'-nbsp'}) {
1644 $str =~ s/ /&nbsp;/g;
1645 }
1646 $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1647 return $str;
1648 }
1649
1650 # quote control characters and escape filename to HTML
1651 sub esc_path {
1652 my $str = shift;
1653 my %opts = @_;
1654
1655 return undef unless defined $str;
1656
1657 $str = to_utf8($str);
1658 $str = $cgi->escapeHTML($str);
1659 if ($opts{'-nbsp'}) {
1660 $str =~ s/ /&nbsp;/g;
1661 }
1662 $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1663 return $str;
1664 }
1665
1666 # Sanitize for use in XHTML + application/xml+xhtml (valid XML 1.0)
1667 sub sanitize {
1668 my $str = shift;
1669
1670 return undef unless defined $str;
1671
1672 $str = to_utf8($str);
1673 $str =~ s|([[:cntrl:]])|(index("\t\n\r", $1) != -1 ? $1 : quot_cec($1))|eg;
1674 return $str;
1675 }
1676
1677 # Make control characters "printable", using character escape codes (CEC)
1678 sub quot_cec {
1679 my $cntrl = shift;
1680 my %opts = @_;
1681 my %es = ( # character escape codes, aka escape sequences
1682 "\t" => '\t', # tab (HT)
1683 "\n" => '\n', # line feed (LF)
1684 "\r" => '\r', # carriage return (CR)
1685 "\f" => '\f', # form feed (FF)
1686 "\b" => '\b', # backspace (BS)
1687 "\a" => '\a', # alarm (bell) (BEL)
1688 "\e" => '\e', # escape (ESC)
1689 "\013" => '\v', # vertical tab (VT)
1690 "\000" => '\0', # nul character (NUL)
1691 );
1692 my $chr = ( (exists $es{$cntrl})
1693 ? $es{$cntrl}
1694 : sprintf('\%2x', ord($cntrl)) );
1695 if ($opts{-nohtml}) {
1696 return $chr;
1697 } else {
1698 return "<span class=\"cntrl\">$chr</span>";
1699 }
1700 }
1701
1702 # Alternatively use unicode control pictures codepoints,
1703 # Unicode "printable representation" (PR)
1704 sub quot_upr {
1705 my $cntrl = shift;
1706 my %opts = @_;
1707
1708 my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1709 if ($opts{-nohtml}) {
1710 return $chr;
1711 } else {
1712 return "<span class=\"cntrl\">$chr</span>";
1713 }
1714 }
1715
1716 # git may return quoted and escaped filenames
1717 sub unquote {
1718 my $str = shift;
1719
1720 sub unq {
1721 my $seq = shift;
1722 my %es = ( # character escape codes, aka escape sequences
1723 't' => "\t", # tab (HT, TAB)
1724 'n' => "\n", # newline (NL)
1725 'r' => "\r", # return (CR)
1726 'f' => "\f", # form feed (FF)
1727 'b' => "\b", # backspace (BS)
1728 'a' => "\a", # alarm (bell) (BEL)
1729 'e' => "\e", # escape (ESC)
1730 'v' => "\013", # vertical tab (VT)
1731 );
1732
1733 if ($seq =~ m/^[0-7]{1,3}$/) {
1734 # octal char sequence
1735 return chr(oct($seq));
1736 } elsif (exists $es{$seq}) {
1737 # C escape sequence, aka character escape code
1738 return $es{$seq};
1739 }
1740 # quoted ordinary character
1741 return $seq;
1742 }
1743
1744 if ($str =~ m/^"(.*)"$/) {
1745 # needs unquoting
1746 $str = $1;
1747 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1748 }
1749 return $str;
1750 }
1751
1752 # escape tabs (convert tabs to spaces)
1753 sub untabify {
1754 my $line = shift;
1755
1756 while ((my $pos = index($line, "\t")) != -1) {
1757 if (my $count = (8 - ($pos % 8))) {
1758 my $spaces = ' ' x $count;
1759 $line =~ s/\t/$spaces/;
1760 }
1761 }
1762
1763 return $line;
1764 }
1765
1766 sub project_in_list {
1767 my $project = shift;
1768 my @list = git_get_projects_list();
1769 return @list && scalar(grep { $_->{'path'} eq $project } @list);
1770 }
1771
1772 ## ----------------------------------------------------------------------
1773 ## HTML aware string manipulation
1774
1775 # Try to chop given string on a word boundary between position
1776 # $len and $len+$add_len. If there is no word boundary there,
1777 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1778 # (marking chopped part) would be longer than given string.
1779 sub chop_str {
1780 my $str = shift;
1781 my $len = shift;
1782 my $add_len = shift || 10;
1783 my $where = shift || 'right'; # 'left' | 'center' | 'right'
1784
1785 # Make sure perl knows it is utf8 encoded so we don't
1786 # cut in the middle of a utf8 multibyte char.
1787 $str = to_utf8($str);
1788
1789 # allow only $len chars, but don't cut a word if it would fit in $add_len
1790 # if it doesn't fit, cut it if it's still longer than the dots we would add
1791 # remove chopped character entities entirely
1792
1793 # when chopping in the middle, distribute $len into left and right part
1794 # return early if chopping wouldn't make string shorter
1795 if ($where eq 'center') {
1796 return $str if ($len + 5 >= length($str)); # filler is length 5
1797 $len = int($len/2);
1798 } else {
1799 return $str if ($len + 4 >= length($str)); # filler is length 4
1800 }
1801
1802 # regexps: ending and beginning with word part up to $add_len
1803 my $endre = qr/.{$len}\w{0,$add_len}/;
1804 my $begre = qr/\w{0,$add_len}.{$len}/;
1805
1806 if ($where eq 'left') {
1807 $str =~ m/^(.*?)($begre)$/;
1808 my ($lead, $body) = ($1, $2);
1809 if (length($lead) > 4) {
1810 $lead = " ...";
1811 }
1812 return "$lead$body";
1813
1814 } elsif ($where eq 'center') {
1815 $str =~ m/^($endre)(.*)$/;
1816 my ($left, $str) = ($1, $2);
1817 $str =~ m/^(.*?)($begre)$/;
1818 my ($mid, $right) = ($1, $2);
1819 if (length($mid) > 5) {
1820 $mid = " ... ";
1821 }
1822 return "$left$mid$right";
1823
1824 } else {
1825 $str =~ m/^($endre)(.*)$/;
1826 my $body = $1;
1827 my $tail = $2;
1828 if (length($tail) > 4) {
1829 $tail = "... ";
1830 }
1831 return "$body$tail";
1832 }
1833 }
1834
1835 # takes the same arguments as chop_str, but also wraps a <span> around the
1836 # result with a title attribute if it does get chopped. Additionally, the
1837 # string is HTML-escaped.
1838 sub chop_and_escape_str {
1839 my ($str) = @_;
1840
1841 my $chopped = chop_str(@_);
1842 $str = to_utf8($str);
1843 if ($chopped eq $str) {
1844 return esc_html($chopped);
1845 } else {
1846 $str =~ s/[[:cntrl:]]/?/g;
1847 return $cgi->span({-title=>$str}, esc_html($chopped));
1848 }
1849 }
1850
1851 # Highlight selected fragments of string, using given CSS class,
1852 # and escape HTML. It is assumed that fragments do not overlap.
1853 # Regions are passed as list of pairs (array references).
1854 #
1855 # Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1856 # '<span class="mark">foo</span>bar'
1857 sub esc_html_hl_regions {
1858 my ($str, $css_class, @sel) = @_;
1859 my %opts = grep { ref($_) ne 'ARRAY' } @sel;
1860 @sel = grep { ref($_) eq 'ARRAY' } @sel;
1861 return esc_html($str, %opts) unless @sel;
1862
1863 my $out = '';
1864 my $pos = 0;
1865
1866 for my $s (@sel) {
1867 my ($begin, $end) = @$s;
1868
1869 # Don't create empty <span> elements.
1870 next if $end <= $begin;
1871
1872 my $escaped = esc_html(substr($str, $begin, $end - $begin),
1873 %opts);
1874
1875 $out .= esc_html(substr($str, $pos, $begin - $pos), %opts)
1876 if ($begin - $pos > 0);
1877 $out .= $cgi->span({-class => $css_class}, $escaped);
1878
1879 $pos = $end;
1880 }
1881 $out .= esc_html(substr($str, $pos), %opts)
1882 if ($pos < length($str));
1883
1884 return $out;
1885 }
1886
1887 # return positions of beginning and end of each match
1888 sub matchpos_list {
1889 my ($str, $regexp) = @_;
1890 return unless (defined $str && defined $regexp);
1891
1892 my @matches;
1893 while ($str =~ /$regexp/g) {
1894 push @matches, [$-[0], $+[0]];
1895 }
1896 return @matches;
1897 }
1898
1899 # highlight match (if any), and escape HTML
1900 sub esc_html_match_hl {
1901 my ($str, $regexp) = @_;
1902 return esc_html($str) unless defined $regexp;
1903
1904 my @matches = matchpos_list($str, $regexp);
1905 return esc_html($str) unless @matches;
1906
1907 return esc_html_hl_regions($str, 'match', @matches);
1908 }
1909
1910
1911 # highlight match (if any) of shortened string, and escape HTML
1912 sub esc_html_match_hl_chopped {
1913 my ($str, $chopped, $regexp) = @_;
1914 return esc_html_match_hl($str, $regexp) unless defined $chopped;
1915
1916 my @matches = matchpos_list($str, $regexp);
1917 return esc_html($chopped) unless @matches;
1918
1919 # filter matches so that we mark chopped string
1920 my $tail = "... "; # see chop_str
1921 unless ($chopped =~ s/\Q$tail\E$//) {
1922 $tail = '';
1923 }
1924 my $chop_len = length($chopped);
1925 my $tail_len = length($tail);
1926 my @filtered;
1927
1928 for my $m (@matches) {
1929 if ($m->[0] > $chop_len) {
1930 push @filtered, [ $chop_len, $chop_len + $tail_len ] if ($tail_len > 0);
1931 last;
1932 } elsif ($m->[1] > $chop_len) {
1933 push @filtered, [ $m->[0], $chop_len + $tail_len ];
1934 last;
1935 }
1936 push @filtered, $m;
1937 }
1938
1939 return esc_html_hl_regions($chopped . $tail, 'match', @filtered);
1940 }
1941
1942 ## ----------------------------------------------------------------------
1943 ## functions returning short strings
1944
1945 # CSS class for given age value (in seconds)
1946 sub age_class {
1947 my $age = shift;
1948
1949 if (!defined $age) {
1950 return "noage";
1951 } elsif ($age < 60*60*2) {
1952 return "age0";
1953 } elsif ($age < 60*60*24*2) {
1954 return "age1";
1955 } else {
1956 return "age2";
1957 }
1958 }
1959
1960 # convert age in seconds to "nn units ago" string
1961 sub age_string {
1962 my $age = shift;
1963 my $age_str;
1964
1965 if ($age > 60*60*24*365*2) {
1966 $age_str = (int $age/60/60/24/365);
1967 $age_str .= " years ago";
1968 } elsif ($age > 60*60*24*(365/12)*2) {
1969 $age_str = int $age/60/60/24/(365/12);
1970 $age_str .= " months ago";
1971 } elsif ($age > 60*60*24*7*2) {
1972 $age_str = int $age/60/60/24/7;
1973 $age_str .= " weeks ago";
1974 } elsif ($age > 60*60*24*2) {
1975 $age_str = int $age/60/60/24;
1976 $age_str .= " days ago";
1977 } elsif ($age > 60*60*2) {
1978 $age_str = int $age/60/60;
1979 $age_str .= " hours ago";
1980 } elsif ($age > 60*2) {
1981 $age_str = int $age/60;
1982 $age_str .= " min ago";
1983 } elsif ($age > 2) {
1984 $age_str = int $age;
1985 $age_str .= " sec ago";
1986 } else {
1987 $age_str .= " right now";
1988 }
1989 return $age_str;
1990 }
1991
1992 use constant {
1993 S_IFINVALID => 0030000,
1994 S_IFGITLINK => 0160000,
1995 };
1996
1997 # submodule/subproject, a commit object reference
1998 sub S_ISGITLINK {
1999 my $mode = shift;
2000
2001 return (($mode & S_IFMT) == S_IFGITLINK)
2002 }
2003
2004 # convert file mode in octal to symbolic file mode string
2005 sub mode_str {
2006 my $mode = oct shift;
2007
2008 if (S_ISGITLINK($mode)) {
2009 return 'm---------';
2010 } elsif (S_ISDIR($mode & S_IFMT)) {
2011 return 'drwxr-xr-x';
2012 } elsif (S_ISLNK($mode)) {
2013 return 'lrwxrwxrwx';
2014 } elsif (S_ISREG($mode)) {
2015 # git cares only about the executable bit
2016 if ($mode & S_IXUSR) {
2017 return '-rwxr-xr-x';
2018 } else {
2019 return '-rw-r--r--';
2020 };
2021 } else {
2022 return '----------';
2023 }
2024 }
2025
2026 # convert file mode in octal to file type string
2027 sub file_type {
2028 my $mode = shift;
2029
2030 if ($mode !~ m/^[0-7]+$/) {
2031 return $mode;
2032 } else {
2033 $mode = oct $mode;
2034 }
2035
2036 if (S_ISGITLINK($mode)) {
2037 return "submodule";
2038 } elsif (S_ISDIR($mode & S_IFMT)) {
2039 return "directory";
2040 } elsif (S_ISLNK($mode)) {
2041 return "symlink";
2042 } elsif (S_ISREG($mode)) {
2043 return "file";
2044 } else {
2045 return "unknown";
2046 }
2047 }
2048
2049 # convert file mode in octal to file type description string
2050 sub file_type_long {
2051 my $mode = shift;
2052
2053 if ($mode !~ m/^[0-7]+$/) {
2054 return $mode;
2055 } else {
2056 $mode = oct $mode;
2057 }
2058
2059 if (S_ISGITLINK($mode)) {
2060 return "submodule";
2061 } elsif (S_ISDIR($mode & S_IFMT)) {
2062 return "directory";
2063 } elsif (S_ISLNK($mode)) {
2064 return "symlink";
2065 } elsif (S_ISREG($mode)) {
2066 if ($mode & S_IXUSR) {
2067 return "executable";
2068 } else {
2069 return "file";
2070 };
2071 } else {
2072 return "unknown";
2073 }
2074 }
2075
2076
2077 ## ----------------------------------------------------------------------
2078 ## functions returning short HTML fragments, or transforming HTML fragments
2079 ## which don't belong to other sections
2080
2081 # format line of commit message.
2082 sub format_log_line_html {
2083 my $line = shift;
2084
2085 # Potentially abbreviated OID.
2086 my $regex = oid_nlen_regex("7,64");
2087
2088 $line = esc_html($line, -nbsp=>1);
2089 $line =~ s{
2090 \b
2091 (
2092 # The output of "git describe", e.g. v2.10.0-297-gf6727b0
2093 # or hadoop-20160921-113441-20-g094fb7d
2094 (?<!-) # see strbuf_check_tag_ref(). Tags can't start with -
2095 [A-Za-z0-9.-]+
2096 (?!\.) # refs can't end with ".", see check_refname_format()
2097 -g$regex
2098 |
2099 # Just a normal looking Git SHA1
2100 $regex
2101 )
2102 \b
2103 }{
2104 $cgi->a({-href => href(action=>"object", hash=>$1),
2105 -class => "text"}, $1);
2106 }egx;
2107
2108 return $line;
2109 }
2110
2111 # format marker of refs pointing to given object
2112
2113 # the destination action is chosen based on object type and current context:
2114 # - for annotated tags, we choose the tag view unless it's the current view
2115 # already, in which case we go to shortlog view
2116 # - for other refs, we keep the current view if we're in history, shortlog or
2117 # log view, and select shortlog otherwise
2118 sub format_ref_marker {
2119 my ($refs, $id) = @_;
2120 my $markers = '';
2121
2122 if (defined $refs->{$id}) {
2123 foreach my $ref (@{$refs->{$id}}) {
2124 # this code exploits the fact that non-lightweight tags are the
2125 # only indirect objects, and that they are the only objects for which
2126 # we want to use tag instead of shortlog as action
2127 my ($type, $name) = qw();
2128 my $indirect = ($ref =~ s/\^\{\}$//);
2129 # e.g. tags/v2.6.11 or heads/next
2130 if ($ref =~ m!^(.*?)s?/(.*)$!) {
2131 $type = $1;
2132 $name = $2;
2133 } else {
2134 $type = "ref";
2135 $name = $ref;
2136 }
2137
2138 my $class = $type;
2139 $class .= " indirect" if $indirect;
2140
2141 my $dest_action = "shortlog";
2142
2143 if ($indirect) {
2144 $dest_action = "tag" unless $action eq "tag";
2145 } elsif ($action =~ /^(history|(short)?log)$/) {
2146 $dest_action = $action;
2147 }
2148
2149 my $dest = "";
2150 $dest .= "refs/" unless $ref =~ m!^refs/!;
2151 $dest .= $ref;
2152
2153 my $link = $cgi->a({
2154 -href => href(
2155 action=>$dest_action,
2156 hash=>$dest
2157 )}, esc_html($name));
2158
2159 $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
2160 $link . "</span>";
2161 }
2162 }
2163
2164 if ($markers) {
2165 return ' <span class="refs">'. $markers . '</span>';
2166 } else {
2167 return "";
2168 }
2169 }
2170
2171 # format, perhaps shortened and with markers, title line
2172 sub format_subject_html {
2173 my ($long, $short, $href, $extra) = @_;
2174 $extra = '' unless defined($extra);
2175
2176 if (length($short) < length($long)) {
2177 $long =~ s/[[:cntrl:]]/?/g;
2178 return $cgi->a({-href => $href, -class => "list subject",
2179 -title => to_utf8($long)},
2180 esc_html($short)) . $extra;
2181 } else {
2182 return $cgi->a({-href => $href, -class => "list subject"},
2183 esc_html($long)) . $extra;
2184 }
2185 }
2186
2187 # Rather than recomputing the url for an email multiple times, we cache it
2188 # after the first hit. This gives a visible benefit in views where the avatar
2189 # for the same email is used repeatedly (e.g. shortlog).
2190 # The cache is shared by all avatar engines (currently gravatar only), which
2191 # are free to use it as preferred. Since only one avatar engine is used for any
2192 # given page, there's no risk for cache conflicts.
2193 our %avatar_cache = ();
2194
2195 # Compute the picon url for a given email, by using the picon search service over at
2196 # http://www.cs.indiana.edu/picons/search.html
2197 sub picon_url {
2198 my $email = lc shift;
2199 if (!$avatar_cache{$email}) {
2200 my ($user, $domain) = split('@', $email);
2201 $avatar_cache{$email} =
2202 "//www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2203 "$domain/$user/" .
2204 "users+domains+unknown/up/single";
2205 }
2206 return $avatar_cache{$email};
2207 }
2208
2209 # Compute the gravatar url for a given email, if it's not in the cache already.
2210 # Gravatar stores only the part of the URL before the size, since that's the
2211 # one computationally more expensive. This also allows reuse of the cache for
2212 # different sizes (for this particular engine).
2213 sub gravatar_url {
2214 my $email = lc shift;
2215 my $size = shift;
2216 $avatar_cache{$email} ||=
2217 "//www.gravatar.com/avatar/" .
2218 md5_hex($email) . "?s=";
2219 return $avatar_cache{$email} . $size;
2220 }
2221
2222 # Insert an avatar for the given $email at the given $size if the feature
2223 # is enabled.
2224 sub git_get_avatar {
2225 my ($email, %opts) = @_;
2226 my $pre_white = ($opts{-pad_before} ? "&nbsp;" : "");
2227 my $post_white = ($opts{-pad_after} ? "&nbsp;" : "");
2228 $opts{-size} ||= 'default';
2229 my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2230 my $url = "";
2231 if ($git_avatar eq 'gravatar') {
2232 $url = gravatar_url($email, $size);
2233 } elsif ($git_avatar eq 'picon') {
2234 $url = picon_url($email);
2235 }
2236 # Other providers can be added by extending the if chain, defining $url
2237 # as needed. If no variant puts something in $url, we assume avatars
2238 # are completely disabled/unavailable.
2239 if ($url) {
2240 return $pre_white .
2241 "<img width=\"$size\" " .
2242 "class=\"avatar\" " .
2243 "src=\"".esc_url($url)."\" " .
2244 "alt=\"\" " .
2245 "/>" . $post_white;
2246 } else {
2247 return "";
2248 }
2249 }
2250
2251 sub format_search_author {
2252 my ($author, $searchtype, $displaytext) = @_;
2253 my $have_search = gitweb_check_feature('search');
2254
2255 if ($have_search) {
2256 my $performed = "";
2257 if ($searchtype eq 'author') {
2258 $performed = "authored";
2259 } elsif ($searchtype eq 'committer') {
2260 $performed = "committed";
2261 }
2262
2263 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2264 searchtext=>$author,
2265 searchtype=>$searchtype), class=>"list",
2266 title=>"Search for commits $performed by $author"},
2267 $displaytext);
2268
2269 } else {
2270 return $displaytext;
2271 }
2272 }
2273
2274 # format the author name of the given commit with the given tag
2275 # the author name is chopped and escaped according to the other
2276 # optional parameters (see chop_str).
2277 sub format_author_html {
2278 my $tag = shift;
2279 my $co = shift;
2280 my $author = chop_and_escape_str($co->{'author_name'}, @_);
2281 return "<$tag class=\"author\">" .
2282 format_search_author($co->{'author_name'}, "author",
2283 git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2284 $author) .
2285 "</$tag>";
2286 }
2287
2288 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2289 sub format_git_diff_header_line {
2290 my $line = shift;
2291 my $diffinfo = shift;
2292 my ($from, $to) = @_;
2293
2294 if ($diffinfo->{'nparents'}) {
2295 # combined diff
2296 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2297 if ($to->{'href'}) {
2298 $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2299 esc_path($to->{'file'}));
2300 } else { # file was deleted (no href)
2301 $line .= esc_path($to->{'file'});
2302 }
2303 } else {
2304 # "ordinary" diff
2305 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2306 if ($from->{'href'}) {
2307 $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2308 'a/' . esc_path($from->{'file'}));
2309 } else { # file was added (no href)
2310 $line .= 'a/' . esc_path($from->{'file'});
2311 }
2312 $line .= ' ';
2313 if ($to->{'href'}) {
2314 $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2315 'b/' . esc_path($to->{'file'}));
2316 } else { # file was deleted
2317 $line .= 'b/' . esc_path($to->{'file'});
2318 }
2319 }
2320
2321 return "<div class=\"diff header\">$line</div>\n";
2322 }
2323
2324 # format extended diff header line, before patch itself
2325 sub format_extended_diff_header_line {
2326 my $line = shift;
2327 my $diffinfo = shift;
2328 my ($from, $to) = @_;
2329
2330 # match <path>
2331 if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2332 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2333 esc_path($from->{'file'}));
2334 }
2335 if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2336 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2337 esc_path($to->{'file'}));
2338 }
2339 # match single <mode>
2340 if ($line =~ m/\s(\d{6})$/) {
2341 $line .= '<span class="info"> (' .
2342 file_type_long($1) .
2343 ')</span>';
2344 }
2345 # match <hash>
2346 if ($line =~ oid_nlen_prefix_infix_regex($sha1_len, "index ", ",") |
2347 $line =~ oid_nlen_prefix_infix_regex($sha256_len, "index ", ",")) {
2348 # can match only for combined diff
2349 $line = 'index ';
2350 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2351 if ($from->{'href'}[$i]) {
2352 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2353 -class=>"hash"},
2354 substr($diffinfo->{'from_id'}[$i],0,7));
2355 } else {
2356 $line .= '0' x 7;
2357 }
2358 # separator
2359 $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2360 }
2361 $line .= '..';
2362 if ($to->{'href'}) {
2363 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2364 substr($diffinfo->{'to_id'},0,7));
2365 } else {
2366 $line .= '0' x 7;
2367 }
2368
2369 } elsif ($line =~ oid_nlen_prefix_infix_regex($sha1_len, "index ", "..") |
2370 $line =~ oid_nlen_prefix_infix_regex($sha256_len, "index ", "..")) {
2371 # can match only for ordinary diff
2372 my ($from_link, $to_link);
2373 if ($from->{'href'}) {
2374 $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2375 substr($diffinfo->{'from_id'},0,7));
2376 } else {
2377 $from_link = '0' x 7;
2378 }
2379 if ($to->{'href'}) {
2380 $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2381 substr($diffinfo->{'to_id'},0,7));
2382 } else {
2383 $to_link = '0' x 7;
2384 }
2385 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2386 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2387 }
2388
2389 return $line . "<br/>\n";
2390 }
2391
2392 # format from-file/to-file diff header
2393 sub format_diff_from_to_header {
2394 my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2395 my $line;
2396 my $result = '';
2397
2398 $line = $from_line;
2399 #assert($line =~ m/^---/) if DEBUG;
2400 # no extra formatting for "^--- /dev/null"
2401 if (! $diffinfo->{'nparents'}) {
2402 # ordinary (single parent) diff
2403 if ($line =~ m!^--- "?a/!) {
2404 if ($from->{'href'}) {
2405 $line = '--- a/' .
2406 $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2407 esc_path($from->{'file'}));
2408 } else {
2409 $line = '--- a/' .
2410 esc_path($from->{'file'});
2411 }
2412 }
2413 $result .= qq!<div class="diff from_file">$line</div>\n!;
2414
2415 } else {
2416 # combined diff (merge commit)
2417 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2418 if ($from->{'href'}[$i]) {
2419 $line = '--- ' .
2420 $cgi->a({-href=>href(action=>"blobdiff",
2421 hash_parent=>$diffinfo->{'from_id'}[$i],
2422 hash_parent_base=>$parents[$i],
2423 file_parent=>$from->{'file'}[$i],
2424 hash=>$diffinfo->{'to_id'},
2425 hash_base=>$hash,
2426 file_name=>$to->{'file'}),
2427 -class=>"path",
2428 -title=>"diff" . ($i+1)},
2429 $i+1) .
2430 '/' .
2431 $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2432 esc_path($from->{'file'}[$i]));
2433 } else {
2434 $line = '--- /dev/null';
2435 }
2436 $result .= qq!<div class="diff from_file">$line</div>\n!;
2437 }
2438 }
2439
2440 $line = $to_line;
2441 #assert($line =~ m/^\+\+\+/) if DEBUG;
2442 # no extra formatting for "^+++ /dev/null"
2443 if ($line =~ m!^\+\+\+ "?b/!) {
2444 if ($to->{'href'}) {
2445 $line = '+++ b/' .
2446 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2447 esc_path($to->{'file'}));
2448 } else {
2449 $line = '+++ b/' .
2450 esc_path($to->{'file'});
2451 }
2452 }
2453 $result .= qq!<div class="diff to_file">$line</div>\n!;
2454
2455 return $result;
2456 }
2457
2458 # create note for patch simplified by combined diff
2459 sub format_diff_cc_simplified {
2460 my ($diffinfo, @parents) = @_;
2461 my $result = '';
2462
2463 $result .= "<div class=\"diff header\">" .
2464 "diff --cc ";
2465 if (!is_deleted($diffinfo)) {
2466 $result .= $cgi->a({-href => href(action=>"blob",
2467 hash_base=>$hash,
2468 hash=>$diffinfo->{'to_id'},
2469 file_name=>$diffinfo->{'to_file'}),
2470 -class => "path"},
2471 esc_path($diffinfo->{'to_file'}));
2472 } else {
2473 $result .= esc_path($diffinfo->{'to_file'});
2474 }
2475 $result .= "</div>\n" . # class="diff header"
2476 "<div class=\"diff nodifferences\">" .
2477 "Simple merge" .
2478 "</div>\n"; # class="diff nodifferences"
2479
2480 return $result;
2481 }
2482
2483 sub diff_line_class {
2484 my ($line, $from, $to) = @_;
2485
2486 # ordinary diff
2487 my $num_sign = 1;
2488 # combined diff
2489 if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2490 $num_sign = scalar @{$from->{'href'}};
2491 }
2492
2493 my @diff_line_classifier = (
2494 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2495 { regexp => qr/^\\/, class => "incomplete" },
2496 { regexp => qr/^ {$num_sign}/, class => "ctx" },
2497 # classifier for context must come before classifier add/rem,
2498 # or we would have to use more complicated regexp, for example
2499 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2500 { regexp => qr/^[+ ]{$num_sign}/, class => "add" },
2501 { regexp => qr/^[- ]{$num_sign}/, class => "rem" },
2502 );
2503 for my $clsfy (@diff_line_classifier) {
2504 return $clsfy->{'class'}
2505 if ($line =~ $clsfy->{'regexp'});
2506 }
2507
2508 # fallback
2509 return "";
2510 }
2511
2512 # assumes that $from and $to are defined and correctly filled,
2513 # and that $line holds a line of chunk header for unified diff
2514 sub format_unidiff_chunk_header {
2515 my ($line, $from, $to) = @_;
2516
2517 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2518 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2519
2520 $from_lines = 0 unless defined $from_lines;
2521 $to_lines = 0 unless defined $to_lines;
2522
2523 if ($from->{'href'}) {
2524 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2525 -class=>"list"}, $from_text);
2526 }
2527 if ($to->{'href'}) {
2528 $to_text = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2529 -class=>"list"}, $to_text);
2530 }
2531 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2532 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2533 return $line;
2534 }
2535
2536 # assumes that $from and $to are defined and correctly filled,
2537 # and that $line holds a line of chunk header for combined diff
2538 sub format_cc_diff_chunk_header {
2539 my ($line, $from, $to) = @_;
2540
2541 my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2542 my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2543
2544 @from_text = split(' ', $ranges);
2545 for (my $i = 0; $i < @from_text; ++$i) {
2546 ($from_start[$i], $from_nlines[$i]) =
2547 (split(',', substr($from_text[$i], 1)), 0);
2548 }
2549
2550 $to_text = pop @from_text;
2551 $to_start = pop @from_start;
2552 $to_nlines = pop @from_nlines;
2553
2554 $line = "<span class=\"chunk_info\">$prefix ";
2555 for (my $i = 0; $i < @from_text; ++$i) {
2556 if ($from->{'href'}[$i]) {
2557 $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2558 -class=>"list"}, $from_text[$i]);
2559 } else {
2560 $line .= $from_text[$i];
2561 }
2562 $line .= " ";
2563 }
2564 if ($to->{'href'}) {
2565 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2566 -class=>"list"}, $to_text);
2567 } else {
2568 $line .= $to_text;
2569 }
2570 $line .= " $prefix</span>" .
2571 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2572 return $line;
2573 }
2574
2575 # process patch (diff) line (not to be used for diff headers),
2576 # returning HTML-formatted (but not wrapped) line.
2577 # If the line is passed as a reference, it is treated as HTML and not
2578 # esc_html()'ed.
2579 sub format_diff_line {
2580 my ($line, $diff_class, $from, $to) = @_;
2581
2582 if (ref($line)) {
2583 $line = $$line;
2584 } else {
2585 chomp $line;
2586 $line = untabify($line);
2587
2588 if ($from && $to && $line =~ m/^\@{2} /) {
2589 $line = format_unidiff_chunk_header($line, $from, $to);
2590 } elsif ($from && $to && $line =~ m/^\@{3}/) {
2591 $line = format_cc_diff_chunk_header($line, $from, $to);
2592 } else {
2593 $line = esc_html($line, -nbsp=>1);
2594 }
2595 }
2596
2597 my $diff_classes = "diff";
2598 $diff_classes .= " $diff_class" if ($diff_class);
2599 $line = "<div class=\"$diff_classes\">$line</div>\n";
2600
2601 return $line;
2602 }
2603
2604 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2605 # linked. Pass the hash of the tree/commit to snapshot.
2606 sub format_snapshot_links {
2607 my ($hash) = @_;
2608 my $num_fmts = @snapshot_fmts;
2609 if ($num_fmts > 1) {
2610 # A parenthesized list of links bearing format names.
2611 # e.g. "snapshot (_tar.gz_ _zip_)"
2612 return "snapshot (" . join(' ', map
2613 $cgi->a({
2614 -href => href(
2615 action=>"snapshot",
2616 hash=>$hash,
2617 snapshot_format=>$_
2618 )
2619 }, $known_snapshot_formats{$_}{'display'})
2620 , @snapshot_fmts) . ")";
2621 } elsif ($num_fmts == 1) {
2622 # A single "snapshot" link whose tooltip bears the format name.
2623 # i.e. "_snapshot_"
2624 my ($fmt) = @snapshot_fmts;
2625 return
2626 $cgi->a({
2627 -href => href(
2628 action=>"snapshot",
2629 hash=>$hash,
2630 snapshot_format=>$fmt
2631 ),
2632 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2633 }, "snapshot");
2634 } else { # $num_fmts == 0
2635 return undef;
2636 }
2637 }
2638
2639 ## ......................................................................
2640 ## functions returning values to be passed, perhaps after some
2641 ## transformation, to other functions; e.g. returning arguments to href()
2642
2643 # returns hash to be passed to href to generate gitweb URL
2644 # in -title key it returns description of link
2645 sub get_feed_info {
2646 my $format = shift || 'Atom';
2647 my %res = (action => lc($format));
2648 my $matched_ref = 0;
2649
2650 # feed links are possible only for project views
2651 return unless (defined $project);
2652 # some views should link to OPML, or to generic project feed,
2653 # or don't have specific feed yet (so they should use generic)
2654 return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2655
2656 my $branch = undef;
2657 # branches refs uses 'refs/' + $get_branch_refs()[x] + '/' prefix
2658 # (fullname) to differentiate from tag links; this also makes
2659 # possible to detect branch links
2660 for my $ref (get_branch_refs()) {
2661 if ((defined $hash_base && $hash_base =~ m!^refs/\Q$ref\E/(.*)$!) ||
2662 (defined $hash && $hash =~ m!^refs/\Q$ref\E/(.*)$!)) {
2663 $branch = $1;
2664 $matched_ref = $ref;
2665 last;
2666 }
2667 }
2668 # find log type for feed description (title)
2669 my $type = 'log';
2670 if (defined $file_name) {
2671 $type = "history of $file_name";
2672 $type .= "/" if ($action eq 'tree');
2673 $type .= " on '$branch'" if (defined $branch);
2674 } else {
2675 $type = "log of $branch" if (defined $branch);
2676 }
2677
2678 $res{-title} = $type;
2679 $res{'hash'} = (defined $branch ? "refs/$matched_ref/$branch" : undef);
2680 $res{'file_name'} = $file_name;
2681
2682 return %res;
2683 }
2684
2685 ## ----------------------------------------------------------------------
2686 ## git utility subroutines, invoking git commands
2687
2688 # returns path to the core git executable and the --git-dir parameter as list
2689 sub git_cmd {
2690 $number_of_git_cmds++;
2691 return $GIT, '--git-dir='.$git_dir;
2692 }
2693
2694 # quote the given arguments for passing them to the shell
2695 # quote_command("command", "arg 1", "arg with ' and ! characters")
2696 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2697 # Try to avoid using this function wherever possible.
2698 sub quote_command {
2699 return join(' ',
2700 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2701 }
2702
2703 # get HEAD ref of given project as hash
2704 sub git_get_head_hash {
2705 return git_get_full_hash(shift, 'HEAD');
2706 }
2707
2708 sub git_get_full_hash {
2709 return git_get_hash(@_);
2710 }
2711
2712 sub git_get_short_hash {
2713 return git_get_hash(@_, '--short=7');
2714 }
2715
2716 sub git_get_hash {
2717 my ($project, $hash, @options) = @_;
2718 my $o_git_dir = $git_dir;
2719 my $retval = undef;
2720 $git_dir = "$projectroot/$project";
2721 if (open my $fd, '-|', git_cmd(), 'rev-parse',
2722 '--verify', '-q', @options, $hash) {
2723 $retval = <$fd>;
2724 chomp $retval if defined $retval;
2725 close $fd;
2726 }
2727 if (defined $o_git_dir) {
2728 $git_dir = $o_git_dir;
2729 }
2730 return $retval;
2731 }
2732
2733 # get type of given object
2734 sub git_get_type {
2735 my $hash = shift;
2736
2737 open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2738 my $type = <$fd>;
2739 close $fd or return;
2740 chomp $type;
2741 return $type;
2742 }
2743
2744 # repository configuration
2745 our $config_file = '';
2746 our %config;
2747
2748 # store multiple values for single key as anonymous array reference
2749 # single values stored directly in the hash, not as [ <value> ]
2750 sub hash_set_multi {
2751 my ($hash, $key, $value) = @_;
2752
2753 if (!exists $hash->{$key}) {
2754 $hash->{$key} = $value;
2755 } elsif (!ref $hash->{$key}) {
2756 $hash->{$key} = [ $hash->{$key}, $value ];
2757 } else {
2758 push @{$hash->{$key}}, $value;
2759 }
2760 }
2761
2762 # return hash of git project configuration
2763 # optionally limited to some section, e.g. 'gitweb'
2764 sub git_parse_project_config {
2765 my $section_regexp = shift;
2766 my %config;
2767
2768 local $/ = "\0";
2769
2770 open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2771 or return;
2772
2773 while (my $keyval = <$fh>) {
2774 chomp $keyval;
2775 my ($key, $value) = split(/\n/, $keyval, 2);
2776
2777 hash_set_multi(\%config, $key, $value)
2778 if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2779 }
2780 close $fh;
2781
2782 return %config;
2783 }
2784
2785 # convert config value to boolean: 'true' or 'false'
2786 # no value, number > 0, 'true' and 'yes' values are true
2787 # rest of values are treated as false (never as error)
2788 sub config_to_bool {
2789 my $val = shift;
2790
2791 return 1 if !defined $val; # section.key
2792
2793 # strip leading and trailing whitespace
2794 $val =~ s/^\s+//;
2795 $val =~ s/\s+$//;
2796
2797 return (($val =~ /^\d+$/ && $val) || # section.key = 1
2798 ($val =~ /^(?:true|yes)$/i)); # section.key = true
2799 }
2800
2801 # convert config value to simple decimal number
2802 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2803 # to be multiplied by 1024, 1048576, or 1073741824
2804 sub config_to_int {
2805 my $val = shift;
2806
2807 # strip leading and trailing whitespace
2808 $val =~ s/^\s+//;
2809 $val =~ s/\s+$//;
2810
2811 if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2812 $unit = lc($unit);
2813 # unknown unit is treated as 1
2814 return $num * ($unit eq 'g' ? 1073741824 :
2815 $unit eq 'm' ? 1048576 :
2816 $unit eq 'k' ? 1024 : 1);
2817 }
2818 return $val;
2819 }
2820
2821 # convert config value to array reference, if needed
2822 sub config_to_multi {
2823 my $val = shift;
2824
2825 return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2826 }
2827
2828 sub git_get_project_config {
2829 my ($key, $type) = @_;
2830
2831 return unless defined $git_dir;
2832
2833 # key sanity check
2834 return unless ($key);
2835 # only subsection, if exists, is case sensitive,
2836 # and not lowercased by 'git config -z -l'
2837 if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2838 $lo =~ s/_//g;
2839 $key = join(".", lc($hi), $mi, lc($lo));
2840 return if ($lo =~ /\W/ || $hi =~ /\W/);
2841 } else {
2842 $key = lc($key);
2843 $key =~ s/_//g;
2844 return if ($key =~ /\W/);
2845 }
2846 $key =~ s/^gitweb\.//;
2847
2848 # type sanity check
2849 if (defined $type) {
2850 $type =~ s/^--//;
2851 $type = undef
2852 unless ($type eq 'bool' || $type eq 'int');
2853 }
2854
2855 # get config
2856 if (!defined $config_file ||
2857 $config_file ne "$git_dir/config") {
2858 %config = git_parse_project_config('gitweb');
2859 $config_file = "$git_dir/config";
2860 }
2861
2862 # check if config variable (key) exists
2863 return unless exists $config{"gitweb.$key"};
2864
2865 # ensure given type
2866 if (!defined $type) {
2867 return $config{"gitweb.$key"};
2868 } elsif ($type eq 'bool') {
2869 # backward compatibility: 'git config --bool' returns true/false
2870 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2871 } elsif ($type eq 'int') {
2872 return config_to_int($config{"gitweb.$key"});
2873 }
2874 return $config{"gitweb.$key"};
2875 }
2876
2877 # get hash of given path at given ref
2878 sub git_get_hash_by_path {
2879 my $base = shift;
2880 my $path = shift || return undef;
2881 my $type = shift;
2882
2883 $path =~ s,/+$,,;
2884
2885 open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2886 or die_error(500, "Open git-ls-tree failed");
2887 my $line = <$fd>;
2888 close $fd or return undef;
2889
2890 if (!defined $line) {
2891 # there is no tree or hash given by $path at $base
2892 return undef;
2893 }
2894
2895 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa panic.c'
2896 $line =~ m/^([0-9]+) (.+) ($oid_regex)\t/;
2897 if (defined $type && $type ne $2) {
2898 # type doesn't match
2899 return undef;
2900 }
2901 return $3;
2902 }
2903
2904 # get path of entry with given hash at given tree-ish (ref)
2905 # used to get 'from' filename for combined diff (merge commit) for renames
2906 sub git_get_path_by_hash {
2907 my $base = shift || return;
2908 my $hash = shift || return;
2909
2910 local $/ = "\0";
2911
2912 open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2913 or return undef;
2914 while (my $line = <$fd>) {
2915 chomp $line;
2916
2917 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423 gitweb'
2918 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f gitweb/README'
2919 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2920 close $fd;
2921 return $1;
2922 }
2923 }
2924 close $fd;
2925 return undef;
2926 }
2927
2928 ## ......................................................................
2929 ## git utility functions, directly accessing git repository
2930
2931 # get the value of config variable either from file named as the variable
2932 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2933 # configuration variable in the repository config file.
2934 sub git_get_file_or_project_config {
2935 my ($path, $name) = @_;
2936
2937 $git_dir = "$projectroot/$path";
2938 open my $fd, '<', "$git_dir/$name"
2939 or return git_get_project_config($name);
2940 my $conf = <$fd>;
2941 close $fd;
2942 if (defined $conf) {
2943 chomp $conf;
2944 }
2945 return $conf;
2946 }
2947
2948 sub git_get_project_description {
2949 my $path = shift;
2950 return git_get_file_or_project_config($path, 'description');
2951 }
2952
2953 sub git_get_project_category {
2954 my $path = shift;
2955 return git_get_file_or_project_config($path, 'category');
2956 }
2957
2958
2959 # supported formats:
2960 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2961 # - if its contents is a number, use it as tag weight,
2962 # - otherwise add a tag with weight 1
2963 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2964 # the same value multiple times increases tag weight
2965 # * `gitweb.ctag' multi-valued repo config variable
2966 sub git_get_project_ctags {
2967 my $project = shift;
2968 my $ctags = {};
2969
2970 $git_dir = "$projectroot/$project";
2971 if (opendir my $dh, "$git_dir/ctags") {
2972 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2973 foreach my $tagfile (@files) {
2974 open my $ct, '<', $tagfile
2975 or next;
2976 my $val = <$ct>;
2977 chomp $val if $val;
2978 close $ct;
2979
2980 (my $ctag = $tagfile) =~ s#.*/##;
2981 if ($val =~ /^\d+$/) {
2982 $ctags->{$ctag} = $val;
2983 } else {
2984 $ctags->{$ctag} = 1;
2985 }
2986 }
2987 closedir $dh;
2988
2989 } elsif (open my $fh, '<', "$git_dir/ctags") {
2990 while (my $line = <$fh>) {
2991 chomp $line;
2992 $ctags->{$line}++ if $line;
2993 }
2994 close $fh;
2995
2996 } else {
2997 my $taglist = config_to_multi(git_get_project_config('ctag'));
2998 foreach my $tag (@$taglist) {
2999 $ctags->{$tag}++;
3000 }
3001 }
3002
3003 return $ctags;
3004 }
3005
3006 # return hash, where keys are content tags ('ctags'),
3007 # and values are sum of weights of given tag in every project
3008 sub git_gather_all_ctags {
3009 my $projects = shift;
3010 my $ctags = {};
3011
3012 foreach my $p (@$projects) {
3013 foreach my $ct (keys %{$p->{'ctags'}}) {
3014 $ctags->{$ct} += $p->{'ctags'}->{$ct};
3015 }
3016 }
3017
3018 return $ctags;
3019 }
3020
3021 sub git_populate_project_tagcloud {
3022 my $ctags = shift;
3023
3024 # First, merge different-cased tags; tags vote on casing
3025 my %ctags_lc;
3026 foreach (keys %$ctags) {
3027 $ctags_lc{lc $_}->{count} += $ctags->{$_};
3028 if (not $ctags_lc{lc $_}->{topcount}
3029 or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
3030 $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
3031 $ctags_lc{lc $_}->{topname} = $_;
3032 }
3033 }
3034
3035 my $cloud;
3036 my $matched = $input_params{'ctag'};
3037 if (eval { require HTML::TagCloud; 1; }) {
3038 $cloud = HTML::TagCloud->new;
3039 foreach my $ctag (sort keys %ctags_lc) {
3040 # Pad the title with spaces so that the cloud looks
3041 # less crammed.
3042 my $title = esc_html($ctags_lc{$ctag}->{topname});
3043 $title =~ s/ /&nbsp;/g;
3044 $title =~ s/^/&nbsp;/g;
3045 $title =~ s/$/&nbsp;/g;
3046 if (defined $matched && $matched eq $ctag) {
3047 $title = qq(<span class="match">$title</span>);
3048 }
3049 $cloud->add($title, href(project=>undef, ctag=>$ctag),
3050 $ctags_lc{$ctag}->{count});
3051 }
3052 } else {
3053 $cloud = {};
3054 foreach my $ctag (keys %ctags_lc) {
3055 my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
3056 if (defined $matched && $matched eq $ctag) {
3057 $title = qq(<span class="match">$title</span>);
3058 }
3059 $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
3060 $cloud->{$ctag}{ctag} =
3061 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
3062 }
3063 }
3064 return $cloud;
3065 }
3066
3067 sub git_show_project_tagcloud {
3068 my ($cloud, $count) = @_;
3069 if (ref $cloud eq 'HTML::TagCloud') {
3070 return $cloud->html_and_css($count);
3071 } else {
3072 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
3073 return
3074 '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
3075 join (', ', map {
3076 $cloud->{$_}->{'ctag'}
3077 } splice(@tags, 0, $count)) .
3078 '</div>';
3079 }
3080 }
3081
3082 sub git_get_project_url_list {
3083 my $path = shift;
3084
3085 $git_dir = "$projectroot/$path";
3086 open my $fd, '<', "$git_dir/cloneurl"
3087 or return wantarray ?
3088 @{ config_to_multi(git_get_project_config('url')) } :
3089 config_to_multi(git_get_project_config('url'));
3090 my @git_project_url_list = map { chomp; $_ } <$fd>;
3091 close $fd;
3092
3093 return wantarray ? @git_project_url_list : \@git_project_url_list;
3094 }
3095
3096 sub git_get_projects_list {
3097 my $filter = shift || '';
3098 my $paranoid = shift;
3099 my @list;
3100
3101 if (-d $projects_list) {
3102 # search in directory
3103 my $dir = $projects_list;
3104 # remove the trailing "/"
3105 $dir =~ s!/+$!!;
3106 my $pfxlen = length("$dir");
3107 my $pfxdepth = ($dir =~ tr!/!!);
3108 # when filtering, search only given subdirectory
3109 if ($filter && !$paranoid) {
3110 $dir .= "/$filter";
3111 $dir =~ s!/+$!!;
3112 }
3113
3114 File::Find::find({
3115 follow_fast => 1, # follow symbolic links
3116 follow_skip => 2, # ignore duplicates
3117 dangling_symlinks => 0, # ignore dangling symlinks, silently
3118 wanted => sub {
3119 # global variables
3120 our $project_maxdepth;
3121 our $projectroot;
3122 # skip project-list toplevel, if we get it.
3123 return if (m!^[/.]$!);
3124 # only directories can be git repositories
3125 return unless (-d $_);
3126 # need search permission
3127 return unless (-x $_);
3128 # don't traverse too deep (Find is super slow on os x)
3129 # $project_maxdepth excludes depth of $projectroot
3130 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
3131 $File::Find::prune = 1;
3132 return;
3133 }
3134
3135 my $path = substr($File::Find::name, $pfxlen + 1);
3136 # paranoidly only filter here
3137 if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
3138 next;
3139 }
3140 # we check related file in $projectroot
3141 if (check_export_ok("$projectroot/$path")) {
3142 push @list, { path => $path };
3143 $File::Find::prune = 1;
3144 }
3145 },
3146 }, "$dir");
3147
3148 } elsif (-f $projects_list) {
3149 # read from file(url-encoded):
3150 # 'git%2Fgit.git Linus+Torvalds'
3151 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3152 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3153 open my $fd, '<', $projects_list or return;
3154 PROJECT:
3155 while (my $line = <$fd>) {
3156 chomp $line;
3157 my ($path, $owner) = split ' ', $line;
3158 $path = unescape($path);
3159 $owner = unescape($owner);
3160 if (!defined $path) {
3161 next;
3162 }
3163 # if $filter is rpovided, check if $path begins with $filter
3164 if ($filter && $path !~ m!^\Q$filter\E/!) {
3165 next;
3166 }
3167 if (check_export_ok("$projectroot/$path")) {
3168 my $pr = {
3169 path => $path
3170 };
3171 if ($owner) {
3172 $pr->{'owner'} = to_utf8($owner);
3173 }
3174 push @list, $pr;
3175 }
3176 }
3177 close $fd;
3178 }
3179 return @list;
3180 }
3181
3182 # written with help of Tree::Trie module (Perl Artistic License, GPL compatible)
3183 # as side effects it sets 'forks' field to list of forks for forked projects
3184 sub filter_forks_from_projects_list {
3185 my $projects = shift;
3186
3187 my %trie; # prefix tree of directories (path components)
3188 # generate trie out of those directories that might contain forks
3189 foreach my $pr (@$projects) {
3190 my $path = $pr->{'path'};
3191 $path =~ s/\.git$//; # forks of 'repo.git' are in 'repo/' directory
3192 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
3193 next unless ($path); # skip '.git' repository: tests, git-instaweb
3194 next unless (-d "$projectroot/$path"); # containing directory exists
3195 $pr->{'forks'} = []; # there can be 0 or more forks of project
3196
3197 # add to trie
3198 my @dirs = split('/', $path);
3199 # walk the trie, until either runs out of components or out of trie
3200 my $ref = \%trie;
3201 while (scalar @dirs &&
3202 exists($ref->{$dirs[0]})) {
3203 $ref = $ref->{shift @dirs};
3204 }
3205 # create rest of trie structure from rest of components
3206 foreach my $dir (@dirs) {
3207 $ref = $ref->{$dir} = {};
3208 }
3209 # create end marker, store $pr as a data
3210 $ref->{''} = $pr if (!exists $ref->{''});
3211 }
3212
3213 # filter out forks, by finding shortest prefix match for paths
3214 my @filtered;
3215 PROJECT:
3216 foreach my $pr (@$projects) {
3217 # trie lookup
3218 my $ref = \%trie;
3219 DIR:
3220 foreach my $dir (split('/', $pr->{'path'})) {
3221 if (exists $ref->{''}) {
3222 # found [shortest] prefix, is a fork - skip it
3223 push @{$ref->{''}{'forks'}}, $pr;
3224 next PROJECT;
3225 }
3226 if (!exists $ref->{$dir}) {
3227 # not in trie, cannot have prefix, not a fork
3228 push @filtered, $pr;
3229 next PROJECT;
3230 }
3231 # If the dir is there, we just walk one step down the trie.
3232 $ref = $ref->{$dir};
3233 }
3234 # we ran out of trie
3235 # (shouldn't happen: it's either no match, or end marker)
3236 push @filtered, $pr;
3237 }
3238
3239 return @filtered;
3240 }
3241
3242 # note: fill_project_list_info must be run first,
3243 # for 'descr_long' and 'ctags' to be filled
3244 sub search_projects_list {
3245 my ($projlist, %opts) = @_;
3246 my $tagfilter = $opts{'tagfilter'};
3247 my $search_re = $opts{'search_regexp'};
3248
3249 return @$projlist
3250 unless ($tagfilter || $search_re);
3251
3252 # searching projects require filling to be run before it;
3253 fill_project_list_info($projlist,
3254 $tagfilter ? 'ctags' : (),
3255 $search_re ? ('path', 'descr') : ());
3256 my @projects;
3257 PROJECT:
3258 foreach my $pr (@$projlist) {
3259
3260 if ($tagfilter) {
3261 next unless ref($pr->{'ctags'}) eq 'HASH';
3262 next unless
3263 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3264 }
3265
3266 if ($search_re) {
3267 next unless
3268 $pr->{'path'} =~ /$search_re/ ||
3269 $pr->{'descr_long'} =~ /$search_re/;
3270 }
3271
3272 push @projects, $pr;
3273 }
3274
3275 return @projects;
3276 }
3277
3278 our $gitweb_project_owner = undef;
3279 sub git_get_project_list_from_file {
3280
3281 return if (defined $gitweb_project_owner);
3282
3283 $gitweb_project_owner = {};
3284 # read from file (url-encoded):
3285 # 'git%2Fgit.git Linus+Torvalds'
3286 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3287 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3288 if (-f $projects_list) {
3289 open(my $fd, '<', $projects_list);
3290 while (my $line = <$fd>) {
3291 chomp $line;
3292 my ($pr, $ow) = split ' ', $line;
3293 $pr = unescape($pr);
3294 $ow = unescape($ow);
3295 $gitweb_project_owner->{$pr} = to_utf8($ow);
3296 }
3297 close $fd;
3298 }
3299 }
3300
3301 sub git_get_project_owner {
3302 my $project = shift;
3303 my $owner;
3304
3305 return undef unless $project;
3306 $git_dir = "$projectroot/$project";
3307
3308 if (!defined $gitweb_project_owner) {
3309 git_get_project_list_from_file();
3310 }
3311
3312 if (exists $gitweb_project_owner->{$project}) {
3313 $owner = $gitweb_project_owner->{$project};
3314 }
3315 if (!defined $owner){
3316 $owner = git_get_project_config('owner');
3317 }
3318 if (!defined $owner) {
3319 $owner = get_file_owner("$git_dir");
3320 }
3321
3322 return $owner;
3323 }
3324
3325 sub git_get_last_activity {
3326 my ($path) = @_;
3327 my $fd;
3328
3329 $git_dir = "$projectroot/$path";
3330 open($fd, "-|", git_cmd(), 'for-each-ref',
3331 '--format=%(committer)',
3332 '--sort=-committerdate',
3333 '--count=1',
3334 map { "refs/$_" } get_branch_refs ()) or return;
3335 my $most_recent = <$fd>;
3336 close $fd or return;
3337 if (defined $most_recent &&
3338 $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3339 my $timestamp = $1;
3340 my $age = time - $timestamp;
3341 return ($age, age_string($age));
3342 }
3343 return (undef, undef);
3344 }
3345
3346 # Implementation note: when a single remote is wanted, we cannot use 'git
3347 # remote show -n' because that command always work (assuming it's a remote URL
3348 # if it's not defined), and we cannot use 'git remote show' because that would
3349 # try to make a network roundtrip. So the only way to find if that particular
3350 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3351 # and when we find what we want.
3352 sub git_get_remotes_list {
3353 my $wanted = shift;
3354 my %remotes = ();
3355
3356 open my $fd, '-|' , git_cmd(), 'remote', '-v';
3357 return unless $fd;
3358 while (my $remote = <$fd>) {
3359 chomp $remote;
3360 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3361 next if $wanted and not $remote eq $wanted;
3362 my ($url, $key) = ($1, $2);
3363
3364 $remotes{$remote} ||= { 'heads' => () };
3365 $remotes{$remote}{$key} = $url;
3366 }
3367 close $fd or return;
3368 return wantarray ? %remotes : \%remotes;
3369 }
3370
3371 # Takes a hash of remotes as first parameter and fills it by adding the
3372 # available remote heads for each of the indicated remotes.
3373 sub fill_remote_heads {
3374 my $remotes = shift;
3375 my @heads = map { "remotes/$_" } keys %$remotes;
3376 my @remoteheads = git_get_heads_list(undef, @heads);
3377 foreach my $remote (keys %$remotes) {
3378 $remotes->{$remote}{'heads'} = [ grep {
3379 $_->{'name'} =~ s!^$remote/!!
3380 } @remoteheads ];
3381 }
3382 }
3383
3384 sub git_get_references {
3385 my $type = shift || "";
3386 my %refs;
3387 # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3388 # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3389 open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3390 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3391 or return;
3392
3393 while (my $line = <$fd>) {
3394 chomp $line;
3395 if ($line =~ m!^($oid_regex)\srefs/($type.*)$!) {
3396 if (defined $refs{$1}) {
3397 push @{$refs{$1}}, $2;
3398 } else {
3399 $refs{$1} = [ $2 ];
3400 }
3401 }
3402 }
3403 close $fd or return;
3404 return \%refs;
3405 }
3406
3407 sub git_get_rev_name_tags {
3408 my $hash = shift || return undef;
3409
3410 open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3411 or return;
3412 my $name_rev = <$fd>;
3413 close $fd;
3414
3415 if ($name_rev =~ m|^$hash tags/(.*)$|) {
3416 return $1;
3417 } else {
3418 # catches also '$hash undefined' output
3419 return undef;
3420 }
3421 }
3422
3423 ## ----------------------------------------------------------------------
3424 ## parse to hash functions
3425
3426 sub parse_date {
3427 my $epoch = shift;
3428 my $tz = shift || "-0000";
3429
3430 my %date;
3431 my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3432 my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3433 my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3434 $date{'hour'} = $hour;
3435 $date{'minute'} = $min;
3436 $date{'mday'} = $mday;
3437 $date{'day'} = $days[$wday];
3438 $date{'month'} = $months[$mon];
3439 $date{'rfc2822'} = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3440 $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3441 $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3442 $mday, $months[$mon], $hour ,$min;
3443 $date{'iso-8601'} = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3444 1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3445
3446 my ($tz_sign, $tz_hour, $tz_min) =
3447 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3448 $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3449 my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3450 ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3451 $date{'hour_local'} = $hour;
3452 $date{'minute_local'} = $min;
3453 $date{'tz_local'} = $tz;
3454 $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3455 1900+$year, $mon+1, $mday,
3456 $hour, $min, $sec, $tz);
3457 return %date;
3458 }
3459
3460 sub hide_mailaddrs_if_private {
3461 my $line = shift;
3462 return $line unless gitweb_check_feature('email-privacy');
3463 $line =~ s/<[^@>]+@[^>]+>/<redacted>/g;
3464 return $line;
3465 }
3466
3467 sub parse_tag {
3468 my $tag_id = shift;
3469 my %tag;
3470 my @comment;
3471
3472 open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3473 $tag{'id'} = $tag_id;
3474 while (my $line = <$fd>) {
3475 chomp $line;
3476 if ($line =~ m/^object ($oid_regex)$/) {
3477 $tag{'object'} = $1;
3478 } elsif ($line =~ m/^type (.+)$/) {
3479 $tag{'type'} = $1;
3480 } elsif ($line =~ m/^tag (.+)$/) {
3481 $tag{'name'} = $1;
3482 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3483 $tag{'author'} = hide_mailaddrs_if_private($1);
3484 $tag{'author_epoch'} = $2;
3485 $tag{'author_tz'} = $3;
3486 if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3487 $tag{'author_name'} = $1;
3488 $tag{'author_email'} = $2;
3489 } else {
3490 $tag{'author_name'} = $tag{'author'};
3491 }
3492 } elsif ($line =~ m/--BEGIN/) {
3493 push @comment, $line;
3494 last;
3495 } elsif ($line eq "") {
3496 last;
3497 }
3498 }
3499 push @comment, <$fd>;
3500 $tag{'comment'} = \@comment;
3501 close $fd or return;
3502 if (!defined $tag{'name'}) {
3503 return
3504 };
3505 return %tag
3506 }
3507
3508 sub parse_commit_text {
3509 my ($commit_text, $withparents) = @_;
3510 my @commit_lines = split '\n', $commit_text;
3511 my %co;
3512
3513 pop @commit_lines; # Remove '\0'
3514
3515 if (! @commit_lines) {
3516 return;
3517 }
3518
3519 my $header = shift @commit_lines;
3520 if ($header !~ m/^$oid_regex/) {
3521 return;
3522 }
3523 ($co{'id'}, my @parents) = split ' ', $header;
3524 while (my $line = shift @commit_lines) {
3525 last if $line eq "\n";
3526 if ($line =~ m/^tree ($oid_regex)$/) {
3527 $co{'tree'} = $1;
3528 } elsif ((!defined $withparents) && ($line =~ m/^parent ($oid_regex)$/)) {
3529 push @parents, $1;
3530 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3531 $co{'author'} = hide_mailaddrs_if_private(to_utf8($1));
3532 $co{'author_epoch'} = $2;
3533 $co{'author_tz'} = $3;
3534 if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3535 $co{'author_name'} = $1;
3536 $co{'author_email'} = $2;
3537 } else {
3538 $co{'author_name'} = $co{'author'};
3539 }
3540 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3541 $co{'committer'} = hide_mailaddrs_if_private(to_utf8($1));
3542 $co{'committer_epoch'} = $2;
3543 $co{'committer_tz'} = $3;
3544 if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3545 $co{'committer_name'} = $1;
3546 $co{'committer_email'} = $2;
3547 } else {
3548 $co{'committer_name'} = $co{'committer'};
3549 }
3550 }
3551 }
3552 if (!defined $co{'tree'}) {
3553 return;
3554 };
3555 $co{'parents'} = \@parents;
3556 $co{'parent'} = $parents[0];
3557
3558 foreach my $title (@commit_lines) {
3559 $title =~ s/^ //;
3560 if ($title ne "") {
3561 $co{'title'} = chop_str($title, 80, 5);
3562 # remove leading stuff of merges to make the interesting part visible
3563 if (length($title) > 50) {
3564 $title =~ s/^Automatic //;
3565 $title =~ s/^merge (of|with) /Merge ... /i;
3566 if (length($title) > 50) {
3567 $title =~ s/(http|rsync):\/\///;
3568 }
3569 if (length($title) > 50) {
3570 $title =~ s/(master|www|rsync)\.//;
3571 }
3572 if (length($title) > 50) {
3573 $title =~ s/kernel.org:?//;
3574 }
3575 if (length($title) > 50) {
3576 $title =~ s/\/pub\/scm//;
3577 }
3578 }
3579 $co{'title_short'} = chop_str($title, 50, 5);
3580 last;
3581 }
3582 }
3583 if (! defined $co{'title'} || $co{'title'} eq "") {
3584 $co{'title'} = $co{'title_short'} = '(no commit message)';
3585 }
3586 # remove added spaces, redact e-mail addresses if applicable.
3587 foreach my $line (@commit_lines) {
3588 $line =~ s/^ //;
3589 $line = hide_mailaddrs_if_private($line);
3590 }
3591 $co{'comment'} = \@commit_lines;
3592
3593 my $age = time - $co{'committer_epoch'};
3594 $co{'age'} = $age;
3595 $co{'age_string'} = age_string($age);
3596 my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3597 if ($age > 60*60*24*7*2) {
3598 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3599 $co{'age_string_age'} = $co{'age_string'};
3600 } else {
3601 $co{'age_string_date'} = $co{'age_string'};
3602 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3603 }
3604 return %co;
3605 }
3606
3607 sub parse_commit {
3608 my ($commit_id) = @_;
3609 my %co;
3610
3611 local $/ = "\0";
3612
3613 open my $fd, "-|", git_cmd(), "rev-list",
3614 "--parents",
3615 "--header",
3616 "--max-count=1",
3617 $commit_id,
3618 "--",
3619 or die_error(500, "Open git-rev-list failed");
3620 %co = parse_commit_text(<$fd>, 1);
3621 close $fd;
3622
3623 return %co;
3624 }
3625
3626 sub parse_commits {
3627 my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3628 my @cos;
3629
3630 $maxcount ||= 1;
3631 $skip ||= 0;
3632
3633 local $/ = "\0";
3634
3635 open my $fd, "-|", git_cmd(), "rev-list",
3636 "--header",
3637 @args,
3638 ("--max-count=" . $maxcount),
3639 ("--skip=" . $skip),
3640 @extra_options,
3641 $commit_id,
3642 "--",
3643 ($filename ? ($filename) : ())
3644 or die_error(500, "Open git-rev-list failed");
3645 while (my $line = <$fd>) {
3646 my %co = parse_commit_text($line);
3647 push @cos, \%co;
3648 }
3649 close $fd;
3650
3651 return wantarray ? @cos : \@cos;
3652 }
3653
3654 # parse line of git-diff-tree "raw" output
3655 sub parse_difftree_raw_line {
3656 my $line = shift;
3657 my %res;
3658
3659 # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M ls-files.c'
3660 # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M rev-tree.c'
3661 if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ($oid_regex) ($oid_regex) (.)([0-9]{0,3})\t(.*)$/) {
3662 $res{'from_mode'} = $1;
3663 $res{'to_mode'} = $2;
3664 $res{'from_id'} = $3;
3665 $res{'to_id'} = $4;
3666 $res{'status'} = $5;
3667 $res{'similarity'} = $6;
3668 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3669 ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3670 } else {
3671 $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3672 }
3673 }
3674 # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3675 # combined diff (for merge commit)
3676 elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:$oid_regex )+)([a-zA-Z]+)\t(.*)$//) {
3677 $res{'nparents'} = length($1);
3678 $res{'from_mode'} = [ split(' ', $2) ];
3679 $res{'to_mode'} = pop @{$res{'from_mode'}};
3680 $res{'from_id'} = [ split(' ', $3) ];
3681 $res{'to_id'} = pop @{$res{'from_id'}};
3682 $res{'status'} = [ split('', $4) ];
3683 $res{'to_file'} = unquote($5);
3684 }
3685 # 'c512b523472485aef4fff9e57b229d9d243c967f'
3686 elsif ($line =~ m/^($oid_regex)$/) {
3687 $res{'commit'} = $1;
3688 }
3689
3690 return wantarray ? %res : \%res;
3691 }
3692
3693 # wrapper: return parsed line of git-diff-tree "raw" output
3694 # (the argument might be raw line, or parsed info)
3695 sub parsed_difftree_line {
3696 my $line_or_ref = shift;
3697
3698 if (ref($line_or_ref) eq "HASH") {
3699 # pre-parsed (or generated by hand)
3700 return $line_or_ref;
3701 } else {
3702 return parse_difftree_raw_line($line_or_ref);
3703 }
3704 }
3705
3706 # parse line of git-ls-tree output
3707 sub parse_ls_tree_line {
3708 my $line = shift;
3709 my %opts = @_;
3710 my %res;
3711
3712 if ($opts{'-l'}) {
3713 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa 16717 panic.c'
3714 $line =~ m/^([0-9]+) (.+) ($oid_regex) +(-|[0-9]+)\t(.+)$/s;
3715
3716 $res{'mode'} = $1;
3717 $res{'type'} = $2;
3718 $res{'hash'} = $3;
3719 $res{'size'} = $4;
3720 if ($opts{'-z'}) {
3721 $res{'name'} = $5;
3722 } else {
3723 $res{'name'} = unquote($5);
3724 }
3725 } else {
3726 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa panic.c'
3727 $line =~ m/^([0-9]+) (.+) ($oid_regex)\t(.+)$/s;
3728
3729 $res{'mode'} = $1;
3730 $res{'type'} = $2;
3731 $res{'hash'} = $3;
3732 if ($opts{'-z'}) {
3733 $res{'name'} = $4;
3734 } else {
3735 $res{'name'} = unquote($4);
3736 }
3737 }
3738
3739 return wantarray ? %res : \%res;
3740 }
3741
3742 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3743 sub parse_from_to_diffinfo {
3744 my ($diffinfo, $from, $to, @parents) = @_;
3745
3746 if ($diffinfo->{'nparents'}) {
3747 # combined diff
3748 $from->{'file'} = [];
3749 $from->{'href'} = [];
3750 fill_from_file_info($diffinfo, @parents)
3751 unless exists $diffinfo->{'from_file'};
3752 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3753 $from->{'file'}[$i] =
3754 defined $diffinfo->{'from_file'}[$i] ?
3755 $diffinfo->{'from_file'}[$i] :
3756 $diffinfo->{'to_file'};
3757